Avoid Windows UAC Put Prefs,cs In User's Documents

Torque 3D writes it's temporary files locally - which is not going to happen if it's located in the Program Files directory - which may not be so great for the end user. This resource should put all temporary files like prefs in the user's documents folder.

-----------------

First up, you'll have to decide when you want the prefs to be saved to the user's "home" directory - better know as My Documents. For this demonstration we will simply check if the prefs.cs exists in it's usual place of game/scripts/client - if it does we'll keep using that, if it doesn't we'll try to use the user's own directories.

In reality you would probably want to check if the game is for shipping to make this change, possibly by checking whether it's a tools build or not.

//psuedo code
if(isToolBuild())
   echo("prefs go in game directory");
else
   echo("prefs go in user directory");

The key file is **** scripts/client/defaults.cs **** which executes core/scripts/client/defaults.cs and then calls the prefs file to overwrite any changes.

As stock it looks like this:

// First we execute the core default preferences.
exec( "core/scripts/client/defaults.cs" );


// Now add your own game specific client preferences as
// well as any overloaded core defaults here.
$PhysXLogWarnings = false;



// Finally load the preferences saved from the last
// game execution if they exist.
if ( $platform !$= "xenon" )
{
   if ( isFile( "./prefs.cs" ) )
      exec( "./prefs.cs" );
}
else
{
   echo( "Not loading client prefs.cs on Xbox360" );
}

Xenon ... I think we can dispense with that, can't we ... ;)

We will introdue a new $global for storing the destination of prefs.cs = $prefPath. When setting the $prefPath to the user's directory we have a choice of 2 destinations:
Users/My Documents = getUserHomeDirectory();
or
Users/AppData/Roaming = getUserDataDirectory();

Take your pick, we'll use the Home directory - but if it's unavailable (for whatever horrible reason) we'll try Data directory - and if this fails we'll revert to game directory ... which isn't what we wanted ...

We'll also use the $appName of your game to name the folder in the directory.

//...

// Finally load the preferences saved from the last
// game execution if they exist.
if(isFile("./prefs.cs"))//check for local prefs first
   $prefpath = "scripts/client";
else
{
   echo("no prefs in game directory - let's set the directory to the users");
   %temp = getUserHomeDirectory();
   echo(%temp);
   if(!isDirectory(%temp))
   {
      echo("c2cannot find home user document folder");
      %temp = getUserDataDirectory();
      echo(%temp);
         
      if(!isDirectory(%temp))
      {
         echo("c2cannot find home user appdata roaming folder");
         $prefpath = "scripts";
      }
      else
      {
         //put it in appdata/roaming
         $prefpath = %temp @ "/" @ $appName @ "/scripts";
      }
   }
   else
   {
      //put it in user/documents
      $prefPath = %temp @ "/" @ $appName @ "/scripts";
   }
}

echo("path for preferences = " @ $prefPath);

//and finally execute prefs if the file already exists
if(isFile($prefPath @ "/client/prefs.cs");
   exec($prefPath @ "/client/prefs.cs");

And next up ... exporting our prefs to the new directory. Open up scripts/main.cs. This is how it looks in stock.

//...
   echo("Exporting client prefs");//yorks need to check for prefs.cs destination
   export("$pref::*", "./client/prefs.cs", False);
//...

And this is what we want to change it to:

echo("Exporting client prefs");//yorks need to check for prefs.cs destination
   //export("$pref::*", "./client/prefs.cs", False);
   export("$pref::*", $prefpath @ "/client/prefs.cs", False);//yorks

Disclaimer: I've not bothered with the lower multiplayer stuff as my project is single player only and so I simply commented it out.

However you probably want it in so do the same in main.cs for the server preferences and banlist which are right below the client prefs, and the other files to change are scripts/server/defaults.cs which want to use the $prefPath system and also some server/prefs.cs located in corescriptsserverserver.cs.

There is also custom bind keys to think about in scripts/client/config.cs ---- and ShaderGen doesn't seem to want to cache anywhere but in game/shaders/proceedural, I've not looking into why.

Anyhow that's the gist? ... jist? ... of it all.

If you clean your prefs with the .bat file, restart your project, mess with the options, and save, the new client prefs file should be in a new folder in users/documents/projectname.

One last thing to note if you expand this to use the $prefPath system as a save game folder, games saved to user's directory will automatically be relative/expanded so you need to make a check in core/scripts/server/server.cs and change this:

function createServer(%serverType, %level)
{
//...
   // Make sure our level name is relative so that it can send
   // across the network correctly
   //%level = makeRelativePath(%level, getWorkingDirectory());//yorks out!
   //yorks NO! This will prevent saved games from working

   //yorks start in
   %work = getWorkingDirectory();//yorks new
   %gameDir = isFile(%work @ "/" @ %level);//yorks new
   if(%gameDir)//is level in game directory make path relative else path is already relative
      %level = makeRelativePath(%level, getWorkingDirectory());
   
   echo("c4loading from " @ %level @ " inside game directory = " @ %gameDir);
//yorks end

   destroyServer();
//...