Simple speech for Players

In working on AI stuff, I created a handy utility function to have AIPlayers make sounds based on a simple function call. Instead of remembering the names of SFXProfile datablocks and so on, I wanted to just call a function with a textual representation of what I wanted the character to say. I also wanted the system to be generic enough to handle different voice types.

The solution I came up with revolves around using an ArrayObject to define a character's 'voice'. This array maps text phrases like "ouch", "hello" or "must have been rats" to SFXProfile objects that contain the appropriate sound files for each phrase. Then, to make a Player say the appropriate phrase, you can use text rather than referring to the sound file directly.

Simply paste the following code into a new file 'game/scripts/server/speech.cs':

//-----------------------------------------------------------------------------
// Copyright (c) 2012 Daniel Buckmaster
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to
// deal in the Software without restriction, including without limitation the
// rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
// sell copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in
// all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
// FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
// IN THE SOFTWARE.
//-----------------------------------------------------------------------------

// Players can play up to 4 sounds concurrently in slots 0-3. We'll use slot 0
// for saying things.
$Player::SpeechSlot = 0;

// Say a phrase defined in the voice object given.
function Player::say(%this, %phrase, %voice)
{
   if (!isObject(%voice))
      %voice = DefaultVoice;
   
   %this.stopTalking();
   
   %sound = %voice.getValue(%voice.getIndexFromKey(%phrase));
   if (isObject(%sound))
   {
      %this.playAudio($Player::SpeechSlot, %sound);
      %this.stopTalking = %this.getDataBlock().schedule(
         %sound.getSoundDuration() * 1000,
         "onFinishedTalking",
         %this);
   }
}

// Shut this Player up immediately!
function Player::stopTalking(%this)
{
   %this.stopAudio($Player::SpeechSlot);
   if (%this.stopTalking)
   {
      cancel(%this.stopTalking);
      %this.getDatablock().onFinishedTalking(%this);
   }
}

// Callback when the character finishes playing the speech sound. You can override
// this in other datablock classes, but remember to always call
// Parent::onFinishedTalking(%this, %obj);
function PlayerData::onFinishedTalking(%this, %obj)
{
   %obj.stopTalking = 0;
}

// Define the 'default' voice used.
new ArrayObject(DefaultVoice);
DefaultVoice.add("ouch", PainCrySound);
DefaultVoice.add("ouch!", DeathCrySound);

Note that I assume you're using the Full template, so the SFXProfiles PainCrySound and DeathCrySound already exist.

Then, in 'scriptExec.cs', add the following line somewhere:

exec("./speech.cs");

Away you go! Try calling this in the console:

LocalClientConnection.player.say("ouch");

You can define a new voice object by simply copying the example at the bottom of the script. I haven't included this, but you might want to, for example, add a voice object to each PlayerData block. Then, for example, in a damage script, you could write this:

function PlayerData::onDamage(%this, %obj, %delta)
{
   if(%delta > 0)
      %obj.say("ouch!", %this.voice);
}

Now by giving different datablocks different voice objects, you can change the way each character sounds without having to change any scripts.