Mouse Controls

In this tutorial we will add some mouse controls to the torque options dialog.
First let's add the two new gui controls in the options dialog. So open up optionsDlg.gui (fps/client/ui/optionsDlg.gui) and find the section for the controls Pane. It should read like this:

[b] 
     new GuiControl(OptControlsPane) {
         profile = "GuiWindowProfile";
         horizSizing = "right";
         vertSizing = "bottom";
         position = "9 55";
         extent = "357 208";
         minExtent = "8 8";
         visible = "0";
         helpTag = "0";

[/b]

Notice that it doesnt have any closing brace after the last parameter. That's because we can add other gui controls inside this one, making them childs of the OptControlsPane. So after that block of code add these 2 new gui Controls:

[b] 
         new GuiCheckBoxCtrl() {
            profile = "GuiCheckBoxProfile";
            horizSizing = "right";
            vertSizing = "bottom";
            position = "7 210";
            extent = "140 30";
            minExtent = "8 8";
            visible = "1";
            variable = "$pref::Input::MouseInvert";
            helpTag = "0";
            text = "Invert Mouse?";
            groupNum = "-1";
            buttonType = "ToggleButton";
         };
         new GuiSliderCtrl(OptMouseSensitivity) {
            profile = "GuiSliderProfile";
            horizSizing = "right";
            vertSizing = "bottom";
            position = "179 217";
            extent = "170 34";
            minExtent = "8 8";
            visible = "1";
            variable = "value";
            altCommand = "OptMouseSetSensitivity(OptMouseSensitivity.value);";
            helpTag = "0";
            range = "0.100000 2.000000";
            ticks = "1000";
            value = "0.12375";
         };

[/b]

Ok, notice the first one is a checkbox, we will use this one to set if we want inverted mouse look or normal mouse look. The variable used for this will be $pref::Input::MouseInvert. Then we have a slider, which we'll use to adjust the mouse's sensivity. Notice this one when changed executes the OptMouseSetSensivity() function with the value passed as parameter.
We will now change some sizes from the optionsDlg to make room for the two new controls. In the new GuiControl(OptControlsPane) { change the extent parameter to "357 250".
Now search for new GuiWindowCtrl() { at the top of the file and change its extent parameter to "377 340". Finally look for the following button:

[b] 
      new GuiButtonCtrl() {
         profile = "GuiButtonProfile";
         horizSizing = "right";
         vertSizing = "bottom";
         position = "305 270";
         extent = "60 23";
         minExtent = "8 8";
         visible = "1";
         command = "Canvas.popDialog(optionsDlg);";
         helpTag = "0";
         text = "OK";
      };

[/b]

In this button let's change the position to "305 310". Ok, done with the gui.

Well now open up optionsDlg.cs (fps/client/scripts/optionsDlg.cs) and look for the function OptionsDlg::onWake(%this). At the end of this function add the following line:

[b] 
    OptMouseSensitivity.setValue( $pref::Input::MouseSensitivity);

[/b]

Now add the following code somewhere in optionsDlg.cs. It doesnt really matter where, for example add it at the end of the file.

[b] 
    function OptMouseSetSensitivity(%value)
    {
        $pref::Input::MouseSensitivity = %value;
    }

[/b]

That function sets the $pref variable to the value selected on the slider.
Open up default.bind.cs and search for "function pitch(%val)" change that function so it looks like this one:

[b] 
function pitch(%val)
{
   if($Pref::Input::MouseInvert)
      $mvPitch -= getMouseAdjustAmount(%val);
   else $mvPitch += getMouseAdjustAmount(%val);
}

[/b]

What we changed here is to enable the invert mouse, depending on the state of the Invert Mouse Checkbox, which toggles beetween 1 or 0, this function will adjust the pitch to either positive or negative movement.
Now some lines up you should see the function getMouseAdjustAmount, change it so it looks like this one:

[b] 
function getMouseAdjustAmount(%val)
{
   // based on a default camera fov of 90'
   return((%val * ($cameraFov / 90) * 0.01) * $pref::Input::MouseSensitivity);
}

[/b]

This one determines the movement amount, it multiplies (%val * ($cameraFov / 90) * 0.01) with the value chosen in the slider (which was assigned to the $pref::Input::MouseSenivity variable).

Ok that's all, now go into the game and you should be able to invert the mouse and to adjust its sensivity. If not email me: reivax (at) sinectis (dot) com (dot) ar
Or basically, reivax@sinectis.com.ar :)
Thanks to everyone on that Invert Mouse forum thread !!