Throwing Torque Items

function ShapeBase::throwItem(%this,%data)
{
   // Construct item to throw from the given datablock
   // (with a random rotation around the z axis)
   %item = new Item() {
      dataBlock = %data;
      rotation = "0 0 1 " @ (getRandom() * 360);
   };

   // Make sure the object will be deleted when the
   // mission ends.
   MissionCleanup.add(%item);

   // Call the workhorse throw method...
   %this.throwObject(%item);
}

function ShapeBase::throwObject(%this,%obj)
{
   // Throw the given object in the direction the shape is
   // looking.  The force values are hardcoded...
   %eye = %this.getEyeVector();
   %vec = vectorScale(%eye, 20);

   // Add a vertical component to give the item a better arc
   %dot = vectorDot("0 0 1",%eye);
   if (%dot < 0)
      %dot = -%dot;
   %vec = vectorAdd(%vec,vectorScale("0 0 8",1 - %dot));

   // Add the shape's velocity
   %vec = vectorAdd(%vec,%this.getVelocity());

   // Set the object's position and initial velocity
   %pos = getBoxCenter(%this.getWorldBox());
   %obj.setTransform(%pos);
   %obj.applyImpulse(%pos,%vec);

   // Since the object is thrown from the center of the
   // shape, the object needs to avoid colliding with it's
   // thrower.
   %obj.setCollisionTimeout(%this);
}

datablock Item(Ammo)
{
   shapeFile="./ammo.dts";
};

function serverCmdThrowAmmo(%client)
{
   %client.player.throwItem(Ammo);
}