Weapon fire change

I was doing some work to add a shotgun to the FPS kit, and modified the onfire function a bit

(game/scripts/server/weapon.cs)

function WeaponImage::onFire(%this, %obj, %slot)
{
    //echo("\c4WeaponImage::onFire( "@%this.getName()@", "@%obj.client.nameBase@", "@%slot@" )");

    // Decrement inventory ammo. The image's ammo state is updated
    // automatically by the ammo inventory hooks.
    %obj.decInventory(%this.ammo, 1);
	%iscc = %this.projectileCount;
	if(!%iscc){
		%iscc=1;
	}
    //echo(%iscc);
    for(%isc=0; %isc < %iscc; %isc++){
    	%matrix="";
    	if (%this.projectileSpread)
    	{
    	    // We'll need to "skew" this projectile a little bit.  We start by
    	    // getting the straight ahead aiming point of the gun
    	    %vec = %obj.getMuzzleVector(%slot);

    	    // Then we'll create a spread matrix by randomly generating x, y, and z
    	    // points in a circle
	    %spreadadd=%this.projectileSpread;
	    %playervel=getword(%obj.client.player.getvelocity(),0) + getword(%obj.client.player.getvelocity(),1);
	    if(%playervel > 3 || %playervel < -3){
		%spreadadd+=%this.movingSpread;
	    }
	    %playerjump = getword(%obj.client.player.getvelocity(),2);
	    if(%playerjump>1 || %playerjump<-1){
		%spreadadd+=%this.jumpSpread;
	    }
    	    for(%i = 0; %i < 3; %i++)
    	        %matrix = %matrix @ (getRandom() - 0.5) * 2 * 3.1415926 * %spreadadd @ " ";
    	        %mat = MatrixCreateFromEuler(%matrix);

    	    // Which we'll use to alter the projectile's initial vector with
    	    %muzzleVector = MatrixMulVector(%mat, %vec);
    	}
    	else
    	{
    	    // Weapon doesn't have a spread factor so we fire it using the
    	    // straight ahead aiming point of the gun
    	    %muzzleVector = %obj.getMuzzleVector(%slot);
    	}

    	// Get the player's velocity, we'll then add it to that of the projectile
    	%objectVelocity = %obj.getVelocity();
    	%muzzleVelocity = VectorAdd(
            VectorScale(%muzzleVector, %this.projectile.muzzleVelocity + getrandom(%this.projectile.velocityVariance * -1, %this.projectile.velocityVariance)),
            VectorScale(%objectVelocity, %this.projectile.velInheritFactor));

    	// Create the projectile object
    	%p = new (%this.projectileType)()
    	{
    	    dataBlock = %this.projectile;
    	    initialVelocity = %muzzleVelocity;
    	    initialPosition = %obj.getMuzzlePoint(%slot);
    	    sourceObject = %obj;
    	    sourceSlot = %slot;
    	    client = %obj.client;
    	};
    	MissionCleanup.add(%p);
    }
    // Do some recoil if this weapon has the required field:  recoilType
    if (%this.recoilType !$= "")
        CommandToClient(%obj.client, 'DoRecoil', %this.recoilType);

    return %p;
}

What this does:
-a weapon can shoot multiple projectiles at once
-weapons that have no "projectileCount" set will have it default to 1
-a weapon can be less accurate when the player is moving
-a weapon can be less accurate when the player is jumping(although this is a very basic system which should be expanded upon)
-adds velocityVariance for projectiles

(from the shotgun I added)

//scripted spread system
    projectileSpread = 0.003;
    movingSpread = 0.005;
    jumpSpread = 0.002;

    //projectile count
    projectileCount = 10;

I'd love to see some of these changes in the final release, or at least reproduced by a better scripter than I. But, for the moment, this is mainly a resource for anyone who wants to mess around with the weapons.

Things you can help me with:
-is there anything wrong with the script?
-anyone know how I could improve the jump spread check?

Also: I know there are some indentation issues, I script in a font called terminal so they only show up as wrong here. Just my luck.

Update: cleaned up the movement detection code and thus fixed an issue where standing on a slope would count as moving.
I also added velocityVariance to projectiles, and cleaned up the jump detection code which hopefully should work better now.