Ninja Platformer Help.

function playerClass::onLevelLoaded(%this, %scenegraph)
{
     $pGuy = %this;
      
      moveMap.bindCmd(keyboard, "left", "playerLeft();", "playerLeftStop();");
      moveMap.bindCmd(keyboard, "right", "playerRight();", "playerRightStop();");
      moveMap.bindCmd(keyboard, "space", "playerJump();", "");
      $pGuy.setCollisionMaxIterations(2);
      %force = 20;
      sceneWindow2D.mount($pGuy, "0 0", %force, true);
}

function playerLeft()
{
    $pGuy.moveLeft = true;
    $pGuy.setFlip(true, false);
}

function playerLeftStop()
{
    $pGuy.moveLeft = false;
    
}

function playerRight()
{
     $pGuy.moveRight = true;
     $pGuy.setFlip(false, false);
}

function playerRightStop()
{
     $pGuy.moveRight = false;
}

function playerJump()
{
	%yVelocity = $pGuy.getLinearVelocityY();
	%xVelocity = $pGuy.getLinearVelocityX();

	$pGuy.setLinearVelocityY(100);
	$pGuy.setLinearVelocityX(0);

  	%collision = $pGuy.castCollision(0.005);
    
	if(!(%collision $= ""))
	{
		$pGuy.setLinearVelocityY(-225);
	}
	else
	{
		$pGuy.setLinearVelocityY(%yVelocity);
	}

	$pGuy.setLinearVelocityX(%xVelocity);
}


function playerClass::updateMovement(%this)
{ 
     if(%this.moveLeft)
     {
            %this.setLinearVelocityX(-225);
     }
    
     if(%this.moveRight)
     {
            %this.setLinearVelocityX(225);
     }
    
     if(!%this.moveLeft && !%this.moveRight)
     {
            %this.setLinearVelocityX(0);
     }
     
   
     %yVelocity = $pGuy.getLinearVelocityY();
     $pGuy.setCurrentAnimation(%yVelocity);
                
    $pGuy.setLinearVelocityY(100);
  
    %collision = $pGuy.castCollision(0.005);
    $pGuy.setLinearVelocityY(%yVelocity );
    
    if(%collision $= "")
    {
        $pGuy.setConstantForceY(100);
    }
    else
    {
        $pGuy.setConstantForceY(0);
    } 
}


function t2dSceneGraph::onUpdateScene()
{
       $pGuy.updateMovement();
}


function playerClass::setCurrentAnimation(%this, %yVelocity)
{
   
   if(%yVelocity < 0 )
    {
    	 %this.playAnimation(playerJumpUp);
    }
    else if(%yVelocity > 0 )
    {
    	 %this.playAnimation(playerJumpDown);
    }
    else
    {

       if(%this.moveLeft || %this.moveRight)
       {
           if(%this.getAnimationName() $= "playerRun")
           {
               if(%this.getIsAnimationFinished())
               {
                   %this.playAnimation(playerRun);
               }
           }
           else
           {
               %this.playAnimation(playerRun);
           }
       }   
       else
       {
           %this.playAnimation(playerStand);
       }
    
    }
}