Inventory System, here we go again...

by Vlad I · in Torque Game Builder · 01/11/2012 (11:32 am) · 16 replies · 01/11/2012 (3:02 pm)

// This code only works for a single player game. It will not work with networking since it uses global variables. However, it could be tweaked in order to include multiplayer
// functionality if someone wanted to try.

// Any item you want in your inventory system will need to have the following variables in their datablock:
// name <-- gotta have it. It's the way the code distinguishes one item from another
// amount <--- if you don't add it, it will get added for you but this keeps up with how many the player has in their inventory
// maxAmount <--- if you don't want the player to have a cap on the amounts of items they carry, you'll need to take this out of the addToInventory code. The code will not
//                work if you don't initialize this variable to something other than 0
// type <---- if you want to make specific lists from your inventory such as a list of all the player's weapons, you will need to specify the type of item it is
// salable <---- if you want the player to be able to sell items from their inventory but you don't want everything from the inventory to be salable, this is the way to do
//               it. Set salable to true or false

// create an inventory list
if ( !isObject( $INVENTORY ) )
   $INVENTORY = new SimSet();

// this list will be explained more later
if ( !isObject($LIST))
   $LIST = new SimSet();

// add an object to the inventory
function addToInventory(%item){
         // check to see if we already have at least one of the the same item we're trying to add in our inventory
             if($INVENTORY.isMember(%item)){
                    for(%i = 0; %i < $INVENTORY.getCount(); %i++){
                           if(%item.name $= $INVENTORY.getObject(%i).name){
                                         // found it. Since we already have at least one in the inventory, we will just add 1 to the amount we already have.
                                         %item = $INVENTORY.getObject(%i);
                                         %item.amount++;
                                         // keep this part in if you want there to be a maximum amount of a particular item that the player can hold.
                                         if(%item.amount > %item.maxAmount)
                                                                            %item.amount = %item.maxAmount;
                                        return;
                           }
                    }
             }
             // item doesn't exist in the list. Put it in there
             else{
                  %item.amount++;
                  $INVENTORY.add(%item);
                  $INVENTORY.bringToFront(%item);
             }
}

// remove an item from the inventory
function removeFromInventory(%item){
         %item.amount--;
         echo("Removing "@%item.name@" Amount left "@%item.amount);
         if(%item.amount == 0)
                         $INVENTORY.remove(%item);
}

// checks to see if a specified item is in the inventory, SEND THIS FUNCTION THE ITEM NAME
function nameInInventory(%name){
         for(%i = 0; %i < $INVENTORY.getCount(); %i++){
                %object = $INVENTORY.getObject(%i);
                if(%name $= %object.name)
                         return true;
         }

         return false;
}

// checks to see if a specified item is in the inventory, SEND THIS FUNCTION THE ITEM DATABLOCK
function inInventory(%item){
         for(%i = 0; %i < $INVENTORY.getCount(); %i++){
                %object = $INVENTORY.getObject(%i);
                if(%object.name $= %item.name)
                         return true;
         }

         return false;
}

function getInventorySize(){
         return $INVENTORY.getCount();
}

function inventoryToConsole(){
         $INVENTORY.listObjects();
}

Game Development Community

Inventory System, here we go again...

About the author

Recent Threads