T3D 1.1 Preview - Script Spawned StaticShape has Bad 3D Math - LOGGED (THREED-1670)

by Steve Acaster · in Torque 3D Professional · 04/12/2011 (6:43 am) · 17 replies · starttest()

//staticshape.cs
$Obstacles = $TypeMasks::VehicleObjectType | $TypeMasks::TerrainObjectType | $TypeMasks::StaticTSObjectType | $TypeMasks::StaticShapeObjectType | $TypeMasks::ForestObjectType;

datablock StaticShapeData( testShapedata )
{	
   category = "StaticShape";
   shapeFile = "art/shapes/actors/gideon/gideon.dts";
};

function startTest()
{
//find the player!
	%count = ClientGroup.getCount();
	for (%i = 0; %i < %count; %i++)
	{
		%client = ClientGroup.getObject(%i);
		echo(%client.player);
	}

	echo("Player starting test");
    %eyeVec = %client.player.getEyeVector();

    %startPos = %client.player.getEyePoint();
    %endPos = VectorAdd(%startPos, VectorScale(%eyeVec, 2000));

    %target = ContainerRayCast(%startPos, %endPos, $Obstacles, %client.player);
    %col = firstWord(%target);

	if(%col == 0) 
		return;

	%targetArea = getwords(%target, 1, 3);

	echo(%col SPC %col.getClassname());
	  //return the ID of what we've hit

	 //spawn a particle so we can see the targetArea

	%flare = new ParticleEmitterNode()
	{
         active = "1";
         emitter = "SmokeEmitter";
         velocity = "1";
         dataBlock = "SmokeEmitterNode";
         position = %targetArea;
         rotation = "1 0 0 0";
         scale = "1 1 1";
         locked = "1";
         canSave = "1";
         canSaveDynamicFields = "1";
    };
	MissionCleanup.add(%flare);

	%flare.schedule(10000, "delete");

	//3d math madness!

	//get some height 10 units above terrain
	%targetArea = VectorAdd(%targetArea, "0 0 10");

 // Get the vector from the player to the target
 %vec = %client.player.getForwardVector();

 //create the spawnpoint 50 units to the left of the players view
  %rot = MatrixCreateFromEuler("0 0 " @ mDegToRad(0 - 270));
  %mat = MatrixMulVector(%rot, %vec);
  %start = VectorAdd(%targetArea, VectorScale(%mat, 50));

//next get the rotation to aim at -above- the targetArea
  %vec1n = VectorNormalize(VectorSub(%targetarea, %start));
  %vec2n = VectorNormalize("0 1 0");

  %vdot = VectorDot(%vec1n, %vec2n);
  %angle = mACos(%vdot);

  // convert to degrees and return
  %degangle = mRadToDeg(%angle);

  echo("degangle = " @ %degangle);//this is still [edited! missed that before posting!] up at certain angles

  //add the end point 50 units across
  %rot1 = MatrixCreateFromEuler("0 0 " @ mDegToRad(0 - 90));
  %mat1 = MatrixMulVector(%rot1, %vec);
  %end = VectorAdd(%targetArea, VectorScale(%mat1, 50));

  callNewShape(%start,%degangle,%end);

}

function callNewShape(%start, %degangle, %end)
{
echo("spawnShape");
	%pos1 = new StaticShape()
	{
		dataBlock = TestShapedata;
		position = %start;
		//rotation = "0 0 1 1";//never start at "1 0 0 0" or it all flups up finding angles!
		rotation = "0 0 1 " @ %degangle;//still flups up at various angles inside world space
		scale = "5 5 5";//make him big so we can see easier!
	};
	MissionCleanup.add(%pos1);

	startMoveShape(%pos1, %end);
}

function startMoveShape(%shape, %end)
{
echo("startMoveShape");
	ShapeBase::StartMoveObject(%shape, %end, 8000, 800, 0);

	%shape.schedule(8050, "delete");
}

//=================
//utility functions
//=================

//==============================
function shapebase::getVectorTo(%this, %pos)
{ return VectorSub(%pos, %this.getPosition()); }

function shapebase::getAngleTo(%this, %pos)
{ return shapebase::getAngle(%this.getVectorTo(%pos), %this.getEyeVector()); }

// Return angle between two vectors
function shapebase::getAngle(%vec1, %vec2)
{
  %vec1n = VectorNormalize(%vec1);
  %vec2n = VectorNormalize(%vec2);

  %vdot = VectorDot(%vec1n, %vec2n);
  %angle = mACos(%vdot);

  // convert to degrees and return
  %degangle = mRadToDeg(%angle);
  return %degangle;
}

// these stay, since having to type %rot = %obj.rotFromTransform(%transform); after already having the transform is
// just way too much.
function posFromTransform(%transform)
{
   // the first three words of an object's transform are the object's position
   %position = getWord(%transform, 0) SPC getWord(%transform, 1) SPC getWord(%transform, 2);
   return %position;
}

function rotFromTransform(%transform)
{
   // the last four words of an object's transform are the object's rotation
   %rotation = getWord(%transform, 3) SPC getWord(%transform, 4) SPC getWord(%transform, 5) SPC getWord(%transform, 6);
   return %rotation;
}

//if we are going to make these inherited functions, might as well let them get the transform as well
function SceneObject::posFromTransform(%obj, %transform)
{
   if(%transform $= "")
      %transform = %obj.getTransForm();
   // the first three words of an object's transform are the object's position
   %position = getWord(%transform, 0) SPC getWord(%transform, 1) SPC getWord(%transform, 2);
   return %position;
}

function SceneObject::rotFromTransform(%obj, %transform)
{
   if(%transform $= "")
      %transform = %obj.getTransForm();
   // the last four words of an object's transform are the object's rotation
   %rotation = getWord(%transform, 3) SPC getWord(%transform, 4) SPC getWord(%transform, 5) SPC getWord(%transform, 6);
   return %rotation;
}

function SceneObject::StartMoveObject(%obj, %endpos, %time, %smoothness, %delay)
{
   if(isObject(%obj))
   {
      %startpos = %obj.getTransform();
      %diff = VectorSub(%endpos, %startpos);
      %numsteps = (%time/1000) * %smoothness;
      %interval = 1000 / %smoothness;
      %stepvec = VectorScale(%diff, (1/%numsteps));
      %numstepsleft = %numsteps;
      %currpos = %startpos;
      %obj.MoveObject(%startpos, %endpos, %numsteps, %numstepsleft, %stepvec, %currpos, %interval, %delay);
   }
}

function SceneObject::MoveObject(%obj, %startpos, %endpos, %numsteps, %numstepsleft, %stepvec, %currpos, %interval, %delay)
{
   %rot = rotFromTransform(%obj.getTransform());
   %currpos = VectorAdd(%currpos, %stepvec);

   %obj.setTransForm(%currpos SPC %rot);
   %numstepsleft--;
   if(%numstepsleft < 1)
      return;
   else
      %obj.schedule(%interval, "MoveObject", %startpos, %endpos, %numsteps, %numstepsleft, %stepvec, %currpos, %interval, %delay);
}

Game Development Community

T3D 1.1 Preview - Script Spawned StaticShape has Bad 3D Math - LOGGED (THREED-1670)

About the author

Recent Threads