Creating a door trigger

Someone was asking how to create a trigger to open an animated door.

Only thing I'm not sure about is how to get collision working with the door. As I understand it staticshape doesn't support polysoup and TSStatic doesn't support animation. Someone once told me you can define a collision volume that is associated with the mesh in 3dsmax - is that the best solution and can anyone explain how to do that?

Mini-tutorial
The door needs to be added to the scene as a StaticShape since TSStatic objects don't support animation. Create a StaticShape datablock like this and add it to the bottom of art/datablocks/managedDatablocks.cs:

datablock StaticShapeData(doorDB)
{
   shapeFile = "art/shapes/door/mesh.dts";
   category = "StaticShape";
};

Change the shapeFile line to point to the path to your DTS.

If you restart the world editor you should now find your door under Library->Scripted->StaticShape->doorDB, double click it and it will add your animated door mesh into the scene as a staticShape. Give it a name such as 'testDoor'.

In the shape editor create two animation sequences called 'open' and 'close' showing the relevant parts of the animation. There's an animated door here to play with (doesn't include any collision volume unfortunately):
torque.abigholeintheweb.com/public_system/useruploads/max9_animated_door_example...

In art/datablocks/triggers.cs add a door trigger.

datablock TriggerData( DoorTrigger) {
   tickPeriodMS = 1000;
};

This will test once a second if the player is in the trigger area. You can adjust the tick period if you've got a particularly fast or slow player.


Add a scripts/server/door.cs file like this:

function DoorTrigger::onEnterTrigger( %this, %trigger, %obj) {
   echo("Entered DoorTrigger");
   %trigger.doorRef.playThread( 0, "open");
}

function DoorTrigger::onLeaveTrigger( %this, %trigger, %obj) {
   echo("Left DoorTrigger");
   %trigger.doorRef.playThread( 0, "close");   
}

You can remove the echo statements for production code. This code opens the door when the player enters the trigger area and closes it when they leave.

In scripts/server/scriptExec.cs add a line to include your new script:

exec("./door.cs");

In the scene tree in the T3D world editor select Level->Level->Trigger to add a new trigger. Call it what you want and select 'DoorTrigger' to be the datablock.
Move and scale your trigger volume to the desired size, you want it to cover the area infront and behind your door. In the world editor set 'doorRef' to be 'testDoor' - this is what wires the trigger up to the door.

The door should now open when the player enters the trigger area and close after they leave it.