Iron Sights for Torque3D 1.2

I've always loved using Iron Sights, especialy as I dont like using any ingame huds or gui's or crosshairs.

howTo get them working:

1; BACKUP FILES FIRST!!!!

2; find in lurker.cs and ryder.cs the line

animateOnServer = true;

then directly below that line, add this for the lurker

// Iron Sights begin
   useEyeOffset = false;
   eyeOffset = "0.1 0.4 -0.35";
   DoIronSights   = true;    
   ReturnPosition   = "0.01 0.25 -0.42";  
   IronSightsPosition = "-0.147 -0.225 0.025";  
   // Iron Sights end

and this for the ryder

// Iron Sights begin
   useEyeOffset = false;
   eyeOffset = "0.1 0.4 -0.35";
   DoIronSights   = true;    
   ReturnPosition   = "0.01 0.25 -0.42";  
   IronSightsPosition = "-0.1815 -0.25 0.0495";  
   // Iron Sights end

3; open game/scripts/server/commands.cs, and add these 2 functions to the end of the file

//------------------------------------------------------------------------------
// iron sights functions
//------------------------------------------------------------------------------
function serverCmdDoIronSights(%client,%val)
{
   %curWeapon = %client.player.getMountedImage($WeaponSlot);
   %offset = %curWeapon.IronSightsPosition;
   %canDoIronSights = %curWeapon.DoIronSights;

   if(%canDoIronSights)
   {
      %curWeapon.firstPerson = false;
      %curWeapon.useEyeNode = false;
      %curWeapon.animateOnServer = false;

      commandToClient(%client,'DoIronSights',%client,%curWeapon,%offset);
      %weaponName = %curWeapon.item.getName();
      echo("-->Selected Weapon is " @ %weaponName);
   }

   else if(!%canDoIronSights)
   {
      echo("-->Weapon does not have Iron Sights");
      return;
   }
}

//-----------------------------------------------------------------------------
function serverCmdUndoIronSights(%client,%val)
{
   %curWeapon = %client.player.getMountedImage($WeaponSlot);
   %offset = %curWeapon.ReturnPosition;
   %canDoIronSights = %curWeapon.DoIronSights;

   if(%canDoIronSights)
   {
   %curWeapon.firstPerson = true;
   %curWeapon.useEyeNode = true;
   %curWeapon.animateOnServer = true;
            
   commandToClient(%client,'UndoIronSights',%client,%curWeapon,%offset);
   }

   else if(!%canDoIronSights)
   {
      return;
   }
}

4; now open game/scripts/client/client.cs, and add these 2 functions at the end of the file

//------------------------------------------------------------------------------
// iron sights functions
//------------------------------------------------------------------------------
function clientCmdDoIronSights(%client,%curWeapon,%offset)
{
   %curWeapon.eyeOffset = %offset;
   echo("-->Adjusting EyeOffset to " @ %offset);
}

function clientCmdUndoIronSights(%client,%curWeapon,%offset)
{
   %curWeapon.eyeOffset = %offset;
   echo("-->Returning EyeOffset to " @ %offset);
}

5; next you'll need to open up game/scripts/client/default.bind.cs, and add this function to the end of the file

//------------------------------------------------------------------------------
// iron sights functions
//------------------------------------------------------------------------------
moveMap.bind( mouse, button1, toggleIronSights );
function toggleIronSights( %val )
{
   $mvTriggerCount1++;
   if ( %val == 1 )
     {
      $ZoomOn = true;
      commandToServer( 'DoIronSights' );
      reticle.setVisible(false);
     }
   else if ( %val == 0 )
     {
      $ZoomOn = false;
      commandToServer( 'UndoIronSights' );
      reticle.setVisible(true);
     }
}

6; almost done, find this line in default.bind.cs

moveMap.bind( mouse, button1, mouseButtonZoom );

and replace it with

//moveMap.bind( mouse, button1, mouseButtonZoom );

and you're ready to use Iron Sights with the Lurker and Ryder weapons. press the right mouse button to use the Iron Sights and release the button to return to normal view.

NOTE: the FP arms/weapon models are slightly offset to the left of centre screen, so the weapons are shooting slightly to the right. If anyone can find a way to get them to centre screen, please share your solution here.

pictures in action:





enjoy