Projectile Spread and Shotguns

Download Code File

I believe a lot of developers will find this useful in at least some way so I have
written this small tutorial.

This tutorial does not require any engine modifications whatsoever and only
alters the game script files. In saying this, it should easily work with all versions
of the torque engine.

In this tutorial, any instructions that require editing will be prefixed with ****



PROJECTILE SPREAD AND SHOTGUNS

**** Open the file example/fps/server/scripts/rifle.cs

**** Find the RifleImage datablock. (approx line 271) and add the following lines into the datablock.


projectileSpread = 12/1000; // **** Added in Projectile Spread Tutorial
// This defines the spread of the projectiles. If no value is set the gun will fire
// deadly accurate.

isShotGun = false; // **** Added in Projectile Spread Tutorial
// This defines whether the weapon should act like a shotgun or not.
// Feel free to change as you see fit for fun ;)


The easiest way to imagine projectile spread is to create a circle that has a radius of our projectileSpread.
We then determine a random x y and z within that range and then we effect our normal projectile vector
to use this new random direction.


**** Replace the default RifleImage::onFire function with the following.


function RifleImage::onFire(%this, %obj, %slot)
{
// Decrease the weapons ammo on fire
%obj.decInventory(%this.ammo,1);

// Get the type of projectile we are gonna fire
%projectile = %this.projectile;

// Get the weapons projectile spread and ensure it is never 0
// (we need some spread direction even if it is extremely tiny)
%spread = %this.projectileSpread;
%spread = %spread $= "" ? 0.001 : %spread;
%spread = %spread <= 0 ? 0.001 : %spread;

// Determine if we are using a shotgun class weapon or not
// If we are using a shotgun, set the number of projectiles we are going to fire to 12
%shellcount = 1;
if(%projectile.isShotGun)
%shellcount = 12;

// Create each projectile and send it on its way
for(%shell=0; %shell<%shellcount; %shell++)
{
// Get the muzzle vector. This is the dead straight aiming point of the gun
%vector = %obj.getMuzzleVector(%slot);

// Get our players velocity. We must ensure that the players velocity is added
// onto the projectile
%objectVelocity = %obj.getVelocity();

// Determine scaled projectile vector. This is still in a straight line as
// per the default example
%vector1 = VectorScale(%vector, %projectile.muzzleVelocity);
%vector2 = VectorScale(%objectVelocity, %projectile.velInheritFactor);
%velocity = VectorAdd(%vector1,%vector2);

// Determine our random x, y and z points in our spread circle and create
// a spread matrix.
%x = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
%y = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
%z = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
%mat = MatrixCreateFromEuler(%x @ " " @ %y @ " " @ %z);

// Alter our projectile vector with our spread matrix
%velocity = MatrixMulVector(%mat, %velocity);


// Create our projectile
%p = new (%this.projectileType)()
{
dataBlock = %projectile;
initialVelocity = %velocity;
initialPosition = %obj.getMuzzlePoint(%slot);
sourceObject = %obj;
sourceSlot = %slot;
};
MissionCleanup.add(%p);
}

return %p;
}


That should get projectile spread and shotguns working for you guys.
Try it out and if you have any questions just email me.