Ambient Animations with the StaticShape Class

Ambient animations are usually background animations such as plant swaying, flag waving, etc. They are typically started when the object is constructed and run continuously. This is an example of starting an ambient animation on a static shape using the StaticShape base class/datablock.

In this example we declare a new datablock type call "Flag" and override it's onAdd method to start the animation on the new object. All instances of the "Flag" object will exec this same onAdd script.

The StaticShapeData::create method is provided here only because it's not part of the SDK 1.0 example. This is normally part of your game's basic script support, and is included in the fps demo (SDk 1.2 or higher).

datablock StaticShapeData(Flag)
{
   // The category variable determins where the item
   // shows up in the mission editor's creator tree.
   // (this is misspelled in v1.0, v1.1 or higher should
   // use the correct spelling "category")
   catagory = "Misc";
   shapeFile = "./flag.dts";
};

function Flag::onAdd(%this,%obj)
{
   // %obj is the object being added to the world
   // with %this datablock.  Start up a thread on the
   // new object.  Since the wave sequence is cyclic
   // this animation will run continously.
   %obj.playThread(0,"wave");
}   

function StaticShapeData::create(%block)
{
   // The mission editor invokes this method when it
   // wants to create an object of the given datablock
   // type.  You only need one of these methods for any
   // class/datablock type (in this case StaticShape).
   %obj = new StaticShape()
   {
      dataBlock = %block;
   };
   return(%obj);
}

For this example to work correctly, you need a flag.dts shape with a cyclic animation called "wave".

This code also needs to get executed after the server is created. For SDK v1.0: if you put this into a file, it should be executed from the createServer function in server/scripts/server.cs, or by putting into an existing script file executed by createServer, such as player.cs.

If you have version v1.2 or higher (which you won't at the time I'm posting this) you can add new files to the fps mod's createGame function mod in fps/server/scripts/game.cs

If the script is executed properly, you should see the Flag object in the mission editor's create tree under the Shapes/Misc category.