3D Vector help

%eyeVec = %obj.getForwardVector();

/// <summary>
/// This function calculates the angle between two vectors.  Note! does not
/// take a %this parameter, so must be called scoped: 
/// %angle = AIPlayer::getAngle(%vec1, %vec2);
/// <summary>
/// <param name="vec1">The first vector.</param>
/// <param name="vec2">The second vector.</param>
/// <return>Returns a scalar angle in degrees between the two vectors.</return>
function AIPlayer::getAngle(%vec1, %vec2)
{
  %vec1n = VectorNormalize(%vec1);
  %vec2n = VectorNormalize(%vec2);

  %vdot = VectorDot(%vec1n, %vec2n);
  %angle = mACos(%vdot);

  // convert to degrees and return
  %degangle = mRadToDeg(%angle);
  return %degangle;
}

/// <summary>
/// This function calculates the angle between eye vector and %pos
/// <summary>
/// <param name="pos">The target position.</param>
/// <return>Returns a scalar angle in degrees.</return>
function AIPlayer::getAngleTo(%this, %pos)
{
    return AIPlayer::getAngle(%this.getVectorTo(%pos), %this.getEyeVector());
}

// Return position vector to a position
/// <summary>
/// This function calculates the vector to %pos from eye point
/// <summary>
/// <param name="pos">The target position.</param>
/// <return>Returns a 3D vector from eye pos to target pos (not normalized).</return>
function AIPlayer::getVectorTo(%this, %pos)
{
    if (getWordCount(%pos) < 2 && isObject(%pos))
        %pos = %pos.getPosition();
    return VectorSub(%pos, %this.getPosition());
}

/// <summary>
/// This function gets the direction from the unit to the target.
/// <summary>
/// <param name="target">The target object.</param>
/// <return>Returns a scalar angle in degrees.</return>
function AIPlayer::getTargetDirection(%this, %target)
{
    if (!%target)
        return 0;
    if (%target.getState() $= "dead")
        return 0;
    %tgtPos = %target.player.getPosition();
    %angle = %this.getAngleTo(%tgtPos);
    return %angle;
}

/// <summary>
/// This function determines if the target is within the unit's sight cone.
/// <summary>
/// <param name="objPos">The unit's position.</param>
/// <param name="targetPos">The target's position.</param>
/// <param name="angle">The target's angle off of direct front.</param>
/// <param name="viewAngle">The number of degrees off of forward that the cone extends (1/2 view width).</param>
/// <return>Returns true if the target is in "sight" or false if not.</return>
function AIPlayer::seeTarget(%this, %objPos, %targetPos, %angle, %viewAngle)
{
    if (%viewAngle $= "")
        %viewAngle = 80;
    if ( %angle <= %viewAngle )
    {
        %searchMasks = $TypeMasks::TerrainObjectType | $TypeMasks::StaticTSObjectType | 
            $TypeMasks::InteriorObjectType | $TypeMasks::ShapeBaseObjectType | 
            $TypeMasks::StaticObjectType | $TypeMasks::PlayerObjectType;

        // Search!
        %scanTarg = ContainerRayCast( %objPos, %targetPos, %searchMasks);
        if (%scanTarg)
        {
            %obj = getWord(%scanTarg, 0);
            %type = %obj.getClassName();
            if (%type $= "Player" || %type $= "AiPlayer")
            {
                %this.target = %obj;
                return true;
            }
            else
            {
                %this.target = "";
                return false;
            }
        }
    }
    return false;
}

// then call 
%obj.seeTarget(%obj.position, %target.position, %obj.getAngleTo(%target), 30.0);
// to see if you hit a target within 30 degrees of your forward vector (a 60 degree arc).