Adding

The Torque mission editor as it stands is a fine thing, but one of the seriously lacking features to my mind is the ability to control where a created or pasted object appears within the MissionGroup 'tree'.

Using the following script package, a mapper can select a simGroup in the Mission Tree, which will become the parent of all objects created, or pasted into the 'world'.

// ----
package NMissionEditorHacks
{
// ----

function EditorTree::onSelect( %this, %obj )
{
   %this.selectedObject = %obj;
   parent::onSelect(%this, %obj);
}

function EWorldEditor::copySelection( %this )
{
    %this.copySize = %this.getSelectionSize();
    parent::copySelection(%this);
}

function EWorldEditor::pasteSelection( %this )
{
    parent::pasteSelection(%this);
    // -- add the pasted object to the currently selected group
    if( %pasteTo = EditorTree.getSelectedSimgroup() )
        for(%i = 0; %i < %this.copySize; %i++)
            %pasteTo.add(missionGroup.getObject(missionGroup.getCount() - 1));
}

function Creator::create( %this, %sel )
{
    parent::create(%this, %sel);
    %paste = EWorldEditor.getSelectedObject(0);
    if( %pasteTo = EditorTree.getSelectedSimgroup() )
        %pasteTo.add(%paste);
}

function ObjectBuilderGui::processNewObject( %this, %obj )
{
    parent::processNewObject(%this, %obj);
    if( %pasteTo = EditorTree.getSelectedSimgroup() )
        %pasteTo.add(%obj);
}

function EditorTree::getSelectedSimgroup( %this )
{
    %startGroup = %simGroup = %this.selectedObject;

    // -- make sure the beggar exists
    if( !isObject(%simGroup) )
        return false;

    // -- make sure we're sending back a simGroup
    if( %simGroup.getClassName() !$= "SimGroup" )
        return false;

    // -- make sure the simGroup we have labelled as selected is part of the
    //    mission group.
    while( (%simGroup = %simGroup.getGroup()) != -1 )
        if( %simGroup == MissionGroup.getID() )
            return %startGroup;

    return false;
}

// ----
};
activatePackage(NMissionEditorHacks);
// -----------------------------------------------------------------------------

I'd advise adding this to the "common/editor/EditorGui.cs" script, at the very end, and that's it... all done, the first step to a tidy Mission Tree.

**: updated to include objects created without the use of the ObjectBuilderGUI
**: added 'child of missionGroup' error check
**: grouped the various %pasteTo checks and calls into the EditorTree::getSelectedSimgroup function