Persistant Character Server

Download Code File

Torque Character Server Tutorial
by Daniel Neilsen


DISCLAIMER:
Make sure you back up all your code before doing any of this.

IMPORTANT NOTE: You MUST change this setup for security reasons and to suit your own game. This tutorial is only to give you an indication on how you can do it and shold not be copied verbatim.


This tutorial will show you how to make a remote character server that will integrate with the TGE. This system uses TGE's httpObject to access a php webserver and does NOT directly access any sql or database server for the following reasons:

1) This method requires no username or password to be stored in either the engine code or scripts and hence, has tighter security
2) This method sends the data to php pages which can then run filtering, verification and checking routines on the data to ensure it is real.
3) This method uses CRC32 hashes to verify the data that is transferred


What you will need to use this system:
- A web server that supports php
- A mysql server (or mssql or odbc if you prefer...up to you)
- The TGE (DUH!)



------------------------------------------------------------------
ENGINE MODIFICATIONS

The engine modifications are extremely minimal. The first is a single function that we add to the end of consoleFunctions.cc. This functions allows us to return the CRC32 hash of a string that is compatible with php's CRC32

ConsoleFunction(getStringCRC, S32, 2, 2, "getStringCRC(string)")
{
	argc;
	U32 crcVal;
	crcVal = calculateCRC (argv[1], dStrlen(argv[1]), -1);
	crcVal = (crcVal*-1)-1;
	return(S32(crcVal));
}

The second engine modification is really a hack. At around line 143 in httpObject.cc you will find the following:

if(asciiEscapeTable[c])
      {
         dest[destIndex++] = '%';
         dest[destIndex++] = getHex((c >> 4) & 0xF);
         dest[destIndex++] = getHex(c & 0xF);
      }
      else
         dest[destIndex++] = c;

Change it to:

if(asciiEscapeTable[c])
      {
		 if(c == 9)
		 {
			dest[destIndex++] = '&';
		 }
		 else
		 {
			dest[destIndex++] = '%';
			dest[destIndex++] = getHex((c >> 4) & 0xF);
			dest[destIndex++] = getHex(c & 0xF);
		 }
      }
	  else
         dest[destIndex++] = c;

What this does is allows you to use the text tag \t as & in your get variable strings allowing you to send multiple variables in a single query. (TGE normally dosnt support this and & get turned into its hex equivalent)


Thats all the engine modifications!!


------------------------------------------------------------------
USERNAME/PASSWORD VERIFICATION SCRIPT

The model we are going to use for this assumes a couple of things:

1) Only the game server should EVER talk to the character server, never the client machines
2) The game server should never actually see the players real password for security reasons.



In fps/client/ui/startMissionGui.gui at approx line 153 replace this

%conn.setConnectArgs($pref::Player::Name);

with

%passcrc = getStringCRC($pref::Player::Password) @ ""; // @ "" forces number it to string
%conn.setConnectArgs($pref::Player::Name, %passcrc);


In fps/client/ui/joinServerGui.gui at approx line 327 replace this

%conn.setConnectArgs($pref::Player::Name);

with

%passcrc = getStringCRC($pref::Player::Password) @ ""; // @ "" forces number it to string
%conn.setConnectArgs($pref::Player::Name, %passcrc);


In fps/server/scripts/game.cs add the following (we needed to change this function from common)

function GameConnection::onConnect( %client, %name, %passcrc )
{
   // Send down the connection error info, the client is
   // responsible for displaying this message if a connection
   // error occures.
   messageClient(%client,'MsgConnectionError',"",$Pref::Server::ConnectionError);

   // Send mission information to the client
   sendLoadInfoToClient( %client );

   // Simulated client lag for testing...
   // %client.setSimulatedNetParams(0.1, 30);

   // if hosting this server, set this client to superAdmin
   if (%client.getAddress() $= "local") {
      %client.isAdmin = true;
      %client.isSuperAdmin = true;
   }

   // Get the client's unique id:
   // %authInfo = %client.getAuthInfo();
   // %client.guid = getField( %authInfo, 3 );
   %client.guid = 0;
   addToServerGuidList( %client.guid );


   //*******
   //Store the clients passcrc
   %client.passcrc = %passcrc;
   checkClientLogin(%client, %name, %passcrc);
   //give 30 seconds for response or boot him!
   %client.loginLoop = schedule(30000, 0, "clientLoginFailed", %client);
   //*******

   
   // Set admin status
   %client.isAdmin = false;
   %client.isSuperAdmin = false;

   // Save client preferences on the connection object for later use.
   %client.gender = "Male";
   %client.armor = "Light";
   %client.race = "Human";
   %client.skin = addTaggedString( "base" );
   %client.setPlayerName(%name);
   %client.score = 0;

   // 
   $instantGroup = ServerGroup;
   $instantGroup = MissionCleanup;
   echo("CADD: " @ %client @ " " @ %client.getAddress());

   // Inform the client of all the other clients
   %count = ClientGroup.getCount();
   for (%cl = 0; %cl < %count; %cl++) {
      %other = ClientGroup.getObject(%cl);
      if ((%other != %client)) {
         // These should be "silent" versions of these messages...
         messageClient(%client, 'MsgClientJoin', "", 
               %other.name,
               %other,
               %other.sendGuid,
               %other.score, 
               %other.isAIControlled(),
               %other.isAdmin, 
               %other.isSuperAdmin);
      }
   }

   // Inform the client we've joined up
   messageClient(%client,
      'MsgClientJoin', '\c2Welcome to the Torque demo app %1.', 
      %client.name, 
      %client,
      %client.sendGuid,
      %client.score,
      %client.isAiControlled(), 
      %client.isAdmin, 
      %client.isSuperAdmin);

   // Inform all the other clients of the new guy
   messageAllExcept(%client, -1, 'MsgClientJoin', '\c1%1 joined the game.', 
      %client.name, 
      %client,
      %client.sendGuid,
      %client.score,
      %client.isAiControlled(), 
      %client.isAdmin, 
      %client.isSuperAdmin);

   // If the mission is running, go ahead download it to the client
   if ($missionRunning)
      %client.loadMission();
   $Server::PlayerCount++;
}


//The following settings assumes that the php file
//game_login.php exists at http://www.bla.com/auth/game_login.php
$AuthServer 	= "www.bla.com:80";  	//url and port
$AuthServerPath = "/auth/";  		//server path


function checkClientLogin(%client, %username, %passcrc)
{
	%client.authReturned = false;
	%query 			= "user="@%username@"\t"@
				  "passcrc="@%passcrc@"\r";
	%server 		= $AuthServer;
	%path 			= $AuthServerPath;
	%script 		= %path @ "game_login.php";
	%upd = new HTTPObject(CharLogin);
	%client.sendObject = %upd;		//store object details just in case
	%upd.clientid = %client;
	%upd.get(%server, %script, %query);
}

function CharLogin::onLine( %this, %line )
{
	%client = %this.clientid;
	//Check if webpage returns the word Verified on the frst line
	if(StrStr(%line, "Verified") != -1)
	{
		cancel(%client.loginLoop);
		return;
	}
	
	//otherwise, auth failed!
	error("- ",%line);
	clientLoginFailed(%client);
}

function CharLogin::onConnectionDied( %this )
{
	%client = %this.clientid;
	clientLoginFailed(%client);
}

function CharLogin::onDNSFailed( %this )
{
	%client = %this.clientid;
	clientLoginFailed(%client);
}

function CharLogin::onConnectFailed( %this )
{
	%client = %this.clientid;


	clientLoginFailed(%client);
}

function clientLoginFailed(%client)
{
	//Do what you want to with him.  Auth failed.
	//(This is bad code, you want to improve it)
	%client.delete();
}

Now, although this code WORKS it should be improved to support
some of the following aspects:
1) Multiple server retries in case of packetloss, timeout, etc


---------------------------------------------------------------

Quite obviously this method can also be used for the storage of
persistant character information such as equipment, stats, etc All of these depend upon your game and can be done in this method.

Hope you find this to be some use
Any questions, just ask em :)


Regards
Daniel Neilsen