Torque Vehicle Resource

Download Code File

The following changes can probably be applied to any version of Torque post 1.1.2, including the current CVS head. Follow the instructions carefully. Post any problems or comments as a response to the resource. I extracted these code changes from a more complete system so I apologise profusely if I have left any code snippets out or made any mistakes. Also, this is my first resource, so forgive any obvious/stupid/blatant mistakes.

1) Add the vehicle.cs file into "fps/server/scripts". This file contains generic logic for vehicle management, including mounting and dismounting. There's also a simple function for creating a vehicle when the user presses the appropriate key.

2) Copy the car.cs file from racing/server/scripts/ to fps/server/scripts. Modify any references in the script from:

"~/data/shapes/buggy/";

to:

"~/data/shapes/car/";

3) Add the following to the end of the datablock in car.cs. Note that you must add extra code for each extra seat in your vehicle. If you have extra seats, you must setup the poses and mount point transform for them. The pose just specifies a pose that the player will take when they mount that seat. For example, the driver sits but other passengers may stand. The mount point transform specifies which direction the player faces in that seat.

maxMountSpeed = 0.1;
   mountDelay = 2;
   dismountDelay = 1;

   stationaryThreshold = 0.5;
   maxDismountSpeed = 0.1;
   numMountPoints = 1;
   mountable = true;

   mountPose[0] = "Sitting";
   mountPointTransform[0] = "0 0 0 0 0 1 0";
   isProtectedMountPoint[0] = false;

4) Copy the whole "car" directory from racing/data/shapes/ into fps/data/shapes.

5) Add these lines into the function onServerCreated() in fps/server/scripts/game.cs:

exec("./vehicle.cs");
exec("./car.cs");

6) Add the following to the end of fps/client/scripts/default.bind.cs:

moveMap.bindCmd(keyboard, "e", "commandToServer('MountVehicle');", "");
moveMap.bindCmd(keyboard, "v", "commandToServer('AddCar');", "");

7) Modify player.cs replacing the existing functions with the following. This basically prevents the player from mounting a vehicle by walking into it. It also moves the logic for vehicle management from the player file to vehicle.cs that was added earlier.

function Armor::onMount(%this,%obj,%vehicle,%node)
{
   onPlayerMount(%this,%obj,%vehicle,%node);
}

function Armor::onUnmount( %this, %obj, %vehicle, %node )
{
   onPlayerUnmount(%this, %obj, %vehicle, %node);
}

function Armor::doDismount(%this, %obj, %forced)
{
   doPlayerDismount(%this, %obj, %forced);
}

function Armor::onCollision(%this,%obj,%col,%vec,%speed)
{
   if (%obj.getState() $= "Dead")
      return;

   // Try and pickup all items
   if (%col.getClassName() $= "Item")
      %obj.pickup(%col);
}

8) Add the files vehicleDriverMap.cs vehiclePassengerMap.cs to fps/client/scripts.

9) Add the following two lines to the function initClient() in fps/client/init.cs:

exec("./scripts/vehiclePassengerMap.cs");
   exec("./scripts/vehicleDriverMap.cs");

10) Add the following code to the end of fps/server/scripts/commands.cs. This code is executed when the player presses the key to dismount or change seats in the vehicle.

function serverCmdMountVehicle(%client)
{
   //Determine how far should the picking ray extend into the world?
   %selectRange = 3;

   // Only search for vehicles
   %searchMasks = $TypeMasks::vehicleObjectType;

   %pos = %client.player.getEyePoint();

   // Start with the shape's eye vector...
   %eye = %client.player.getEyeVector();
   %eye = vectorNormalize(%eye);
   %vec = vectorScale(%eye, %selectRange);

   %end = vectorAdd(%vec, %pos);

   %scanTarg = ContainerRayCast (%pos, %end, %searchMasks);

   // a target in range was found so select it
   if (%scanTarg)
   {
      %targetObject = firstWord(%scanTarg);
      echo("Found a vehicle: " @ %targetObject);
      onMountVehicle(%targetObject.getDataBlock(),
                     %client.player,
                     %targetObject);
   }
   else
   {
      echo("No object found");
   }
}

function serverCmdDismountVehicle(%client)
{
   doPlayerDismount(%client, %client.player, %true);
}


function serverCmdFindNextFreeSeat(%client)
{
   echo("serverCmdFindNextFreeSeat " @ %client.nameBase);

   // Is the vehicle moving? If so, prevent the player from switching seats
   if (isVehicleMoving(%client.player.mvehicle) == true)
      return;

   %newSeat = findNextFreeSeat(%client,
                               %client.player.mvehicle,
                               %client.player.mvehicle.getDataBlock());

   if (%newSeat != -1)
   {
      echo("Found new seat " @ %newSeat);

      setActiveSeat(%client.player,
                    %client.player.mvehicle,
                    %client.player.mvehicle.getDataBlock(),
                    %newSeat);
   }
   else
   {
      echo("No next free seat");
   }
}

11) Add the following to the end of fps/client/scripts/client.cs:

function clientCmdPopActionMap(%map)
{
   echo("Popping action map " @ %map);
   %map.pop();
}


function clientCmdPushActionMap(%map)
{
   echo("Pushing action map " @ %map);
   %map.push();
}

12) Comment out the following line in fps/client/scripts/default.bind.cs, otherwise you won't be able to use the 'e' key to enter/exit vehicles.

moveMap.bind(keyboard, e, toggleZoom);