TGEA Seamless Cubemap Builder

Download Code File

Set Up

To start off, create a new script file in your data/server/scripts folder. We've named ours "buildcubemap.cs". Copy/Paste the code at the bottom of this article into your new script file (or download it from the resource link above).

To make sure the code executes when running the game, also include the following line in your game.cs inside the function onServerCreated().

exec("./buildcubemap.cs");

How to Run the thing

Pick the point at which you want the cubemap to be generated from (most likely the center of your room or environment). An easy way I have found to do it is walk your player to that spot, hit F11 to go into the mission editor mode, hit Alt-C to go into free-cam mode, select your player by clicking on them, hit F3 to view the player properties and then scroll down to get the xyz coordinates of where your player is located. Another way is to create an object and just move it to where you want the camera to be, get the xyz location and then delete it.

Open up your console and type the following code but replacing the stuff in quotes with real data.

buildcubemap("x y z", "texture size");

"X Y Z" is the xyz coordinates that you want the cubemap to be generated from. "texture size" is the size of the texture you want to generate.

example: buildcubemap("0 0 0", "512");

That example code would take 6 pictures starting at the origin of the map, and output them as 512x512 .png files into your games root directory.

Important!: This tool literally takes screenshots of torque so make sure you close the mission editor and don't move the mouse while the application is running. Make sure any models that aren't supposed to be in the scene have been removed or they will appear in your cubemaps. If you are also inspecting the code, you will notice that the first image doesn't come out correct so I've added a little piece of code to take that into consideration.

Manual Work

We couldn't figure out how to get the camera to rotate and take the screenshots with the correct orientation so you will need to re-orient the images manually using Photoshop or a similar graphics tool:

ypos - needs to rotate 180
xneg - needs to rotate 90 clockwise
yneg - perfect
xpos - needs to rotate 90 counter-clockwise
zneg - needs to rotate 180
zpos - perfect

All Done

Hopefully from this you have 6 images that will generate a seamless cubemap.

//-----------------------------------------
//buildcubemap.cs
//-----------------------------------------

//build a cubemap of the given size rendered from the given position
function buildcubemap(%position, %size)
{
   %delay = 1000;
   %HalfPI = 3.14159265359 / 2.0;
   
	echo("Building cubemap...");
	
   //save the current settings
   %oldControl = LocalClientConnection.getControlObject();
   %oldMode = canvas.getVideoMode();
   
   //set camera as control object
   LocalClientConnection.setControlObject(LocalClientConnection.camera);
   
   //set resolution
   canvas.setVideoMode(%size, %size, Canvas.isFullScreen());
   
   //turn off console & HUD so it's not in the screenshot
   Canvas.popDialog(ConsoleDlg);
   Canvas.popDialog(MainChatHud);
   
   //the first setTransform doesn't work properly for some reason, let's get it over with now
   LocalClientConnection.camera.schedule(%delay*1, "setTransform", %position @ " 0 0 1 0");
   
   
   //take the 6 screenshots
   //    ideally cubemaps would come out perfect and ready to use, but torque doesn't support
   //    rolling the camera so you'll need to apply the specified rotations manually in photoshop
   LocalClientConnection.camera.schedule(%delay*2, "setTransform", %position @ " 0 0 1 0");              //rotate 180 in photoshop
	schedule(%delay*3, 0, "screenshot", "cubemap_ypos.png", "PNG");
	
   LocalClientConnection.camera.schedule(%delay*4, "setTransform", %position @ " 0 0 1 " @ %HalfPI);     //rotate 90 counter-clockwise in photoshop
	schedule(%delay*5, 0, "screenshot", "cubemap_xpos.png", "PNG");
	
   LocalClientConnection.camera.schedule(%delay*6, "setTransform", %position @ " 0 0 1 " @ %HalfPI*2);
	schedule(%delay*7, 0, "screenshot", "cubemap_yneg.png", "PNG");
	
   LocalClientConnection.camera.schedule(%delay*8, "setTransform", %position @ " 0 0 1 " @ %HalfPI*3);   //rotate 90 clockwise in photoshop
	schedule(%delay*9, 0, "screenshot", "cubemap_xneg.png", "PNG");
	
   LocalClientConnection.camera.schedule(%delay*10, "setTransform", %position @ " 1 0 0 " @ %HalfPI);    //rotate 180 in photoshop
	schedule(%delay*11, 0, "screenshot", "cubemap_zneg.png", "PNG");
	
   LocalClientConnection.camera.schedule(%delay*12, "setTransform", %position @ " -1 0 0 " @ %HalfPI);
	schedule(%delay*13, 0, "screenshot", "cubemap_zpos.png", "PNG");
	
   
   //set the video mode back   
   canvas.schedule(%delay*14, "setVideoMode", getWord(%oldMode, $WORD::RES_X), getWord(%oldMode, $WORD::RES_Y), Canvas.isFullScreen());	
	
	//set the control object back
	LocalClientConnection.schedule(%delay*14, "setControlObject", %oldControl);
	
	//turn console & HUD back on
	canvas.schedule(%delay*14, "pushDialog", ConsoleDlg, 99);
   canvas.schedule(%delay*14, "pushDialog", MainChatHud );
	
	//aaaand we're done!
	schedule(%delay*15, "echo", "Done!");
}