Player Selection

You will need the guiObjectView resource in your engine.

Well after nearly a year and much frustration, I've implemented some form of multiplayer character selection into my project, based off of the Beaver Patrol 1.3 alpha and a player selection post from Gonzo T. Clown. It's linked to a guiObjectView which has a GUI that lets you hit next and previous to view the models and choose the one you like. It has one small flaw, and is in need of some experienced TGE-ers' aid.

Problem:

I think there's something wrong with the calculation or handling of the "next" and "previous" code. Sometimes if you hit Previous, the guiObjectView will be empty, and then you'll have to press Next twice to get back to a model.

It'd be nice for someone to take a look at this code and say "This sucks, here's the right way." :)

How:

After looking through all of these changes they should make some form of sense. I have the soldier pack animations and my own models, so if you want to use this code you will need to change names/animation references to match what you want.

In fps/server/scripts/game.cs, under function GameConnection::createPlayer(%this, %spawnPoint), change the bolded to be what it is below:

// Create the player object
   %player = new Player() {
      [b]dataBlock = %this.armor;[/b]
      client = %this;
   };

Also you will want to put in fps/data/player/ a green.cs, a blue.cs, and a black.cs, with corresponding blue.dts, green.dts, and black.dts player models. (Or just substitute all references to the player models with your own.

In fps/server/scripts/player.cs, at the top, add:

// Load dts shapes and merge animations
//execute the scripts to load the dts values
%filename = "fps/data/shapes/player/*.cs";
$servmodelNum = 0;
for (%file = findFirstFile(%filename); %file !$= ""; %file = findNextFile(%filename)) {
	exec(%file);
}
//Load up the models
%filename = "fps/data/shapes/player/*.dts";
$servmodelNum = 0;
for (%file = findFirstFile(%filename); %file !$= ""; %file = findNextFile(%filename)) {
	if ( %file !$= "fps/data/shapes/player/debris_player.dts" ) {
		$servmodelNum++;
		$servmodelList[$servmodelNum] = %file;
		$servmodelName[$servmodelNum] = fileBase(%file);
	}
}

Then further down, after the entire datablock PlayerData(PlayerBody) section, I've added the player models. I've shortened it to 3 rather than my full 11 for simplicity:

datablock PlayerData (blue : PlayerBody)
{
   shapeFile = "~/data/shapes/player/blue.dts";
};

datablock PlayerData (black : PlayerBody)
{
   shapeFile = "~/data/shapes/player/black.dts";
};

datablock PlayerData (green : PlayerBody)
{
   shapeFile = "~/data/shapes/player/green.dts";
};

Now to the client side. In fps/common/server/clientConnection.cs, change your function GameConnection::onConnect to say:

function GameConnection::onConnect( %client, %name, %armor )

And then right underneath that and its opening bracket, place the following code:

switch$(%armor)
     {
          case "blue":
             %client.armor = "blueArmor";
          case "black":
             %client.armor = "blackArmor";
          case "green":
             %client.armor = "greenArmor";
          default:
             %client.armor = "blueArmor";
     }

Now in fps/client/scripts/, make a new file named playerSetupGui.cs, and in it, put the following and then save it:

function playerSetupGui::onWake(%this)
{
   echo( "Model Name set ---> " @ $pref::Player::Armor );

	//execute the scripts to load the dts values
	%filename = "fps/data/shapes/player/*.cs";
	echo("filename:" @ %filename @ "\n");
	$modelNum = 0;
	for (%file = findFirstFile(%filename); %file !$= ""; %file = findNextFile(%filename)) {
		echo("file:" @ %file @ "\n");
		exec(%file);
	}

	//Load up the models
	%filename = "fps/data/shapes/player/*.dts";
	echo("filename:" @ %filename @ "\n");
	$modelNum = 0;
	for (%file = findFirstFile(%filename); %file !$= ""; %file = findNextFile(%filename)) {
	//  exec(filePath(%file) @ "/player_info.cs");
		//exec(%file);
		//echo("file:" @ %file @ "\n");
		if ( %file !$= "fps/data/shapes/player/debris_player.dts" ) {
			$modelNum++;
			$modelList[$modelNum] = %file;
			$modelName[$modelNum] = fileBase(%file);
			echo("model num " @ $modelNum @ ", model name:" @ $modelName[$modelNum]);
		}
	}
	//Check for valid file name.. we dont want to explode
	%foundnum = 0;
    for ( %i = 0; %i < $modelNum; %i++ )
	{	
		if ( $pref::Player::Armor $= $modelName[%i] ){
		  //Filename is valid
		  %foundnum = %i;
		}
	}

	//if we dont find this model then we have a problem
	//reset it to something safe
	if ( %foundnum == 0  ){
		echo("WARNING MODEL NAME --->" @ $pref::Player::Armor @ " NOT FOUND. Reseting to " @ $modelName[1]);
		$modelCur = 1;
		$pref::Player::Armor = "" @ $modelName[1];
	}

    if ($modelNum > 0) SP_setModel();
}


//------------------------------------------------------------------------------
function playerSetupGui::onSleep(%this)
{

}

function SP_showNextModel()
{
   if ( ($modelCur) == $modelNum )   $modelCur = 1;   // go back to the first model
   else  $modelCur = $modelCur +1;   // go to the next model
   $pref::Player::Armor = "" @ $modelName[$modelCur];
   SP_setModel();
}

function SP_showPrevModel()
{
   if ( $modelCur == 1 )   $modelCur = $modelNum;   // we were at the first model so lets go to the last
	else   $modelCur = $modelCur -1;
   $pref::Player::Armor = "" @ $modelName[$modelCur];
   SP_setModel();
}

function SP_setModel()
{
   echo( "Model Name set ---> " @ $pref::Player::Armor );

   // Set main object
   view.setObject("player", "fps/data/shapes/player/" @ $pref::Player::Armor @ ".dts", "", 0); // set the model that should be showing

   view.loadDSQ("player", "fps/data/shapes/player/soldier_root.dsq"); //load an animation

   view.setSequence("player", "root", "1"); //play the animation
}

Make sure to add an execute line in fps/client/init.cs that reads:

exec("./scripts/playerSetupGui.cs");

Now in fps/client/ui/startMissionGui.gui, in function SM_StartMission(), change %conn.setConnectArgs to say:

%conn.setConnectArgs($pref::Player::Name, $pref::Player::Armor);

Do the same in fps/client/ui/joinServerGui.gui, but in function JoinServerGui::join(%this).

Now just make a nice GUI in which you choose separate models, similar to the following. (I just have the guiObjectView, and the buttons, below)

// Here's where the model is displayed.
      new GuiObjectView(view) { 
         profile = "GuiDefaultProfile";
         horizSizing = "center";
         vertSizing = "center";
         position = "150 150";
         extent = "300 300";
         minExtent = "8 2";
         visible = "1";
         cameraZRot = "0";
         forceFOV = "55";
         lightDirection = "-0.57735 -0.57735 -0.57735";
         lightColor = "0.600000 0.580000 0.500000 1.000000";
         ambientColor = "0.300000 0.300000 0.300000 1.000000";
      };

// This is the Next button
      new GuiBitmapButtonCtrl() {
         profile = "GuiDefaultProfile";
         horizSizing = "right";
         vertSizing = "bottom";
         position = "412 45";
         extent = "180 512";
         minExtent = "8 2";
         visible = "1";
         command = "SP_showNextModel();";
         text = "Button";
         groupNum = "-1";
         buttonType = "PushButton";
         bitmap = "./nextModel";
      };

// This is the Previous button
      new GuiBitmapButtonCtrl() {
         profile = "GuiDefaultProfile";
         horizSizing = "right";
         vertSizing = "bottom";
         position = "18 42";
         extent = "180 512";
         minExtent = "8 2";
         visible = "1";
         command = "SP_showPrevModel();";
         text = "Button";
         groupNum = "-1";
         buttonType = "PushButton";
         bitmap = "./previousModel";
      };

And that should do it. I'm sure everyone would really appreciate help to fix that minor flaw. :)