trigger moving towards

by Anthony Ratcliffe · in Torque Game Builder · 04/28/2009 (2:45 pm) · 24 replies · 1

$enemy = %enemyObject;

function enemyTrigger::onEnter(%this, %object)
  {
    $enemy.moveTo(%object.position());
  }
$enemy = %enemyObject;

function enemyTrigger::onEnter(%this, %object)
  {
    if(%object.class $= "playerClass")
      {
        $enemy.moveTo(%object.position());
      {
  }
function enemyClass::onLevelLoaded(%this, %sceneGraph)
{

   // There is a sprite already loaded in the level builder
   // class was set to enemyClass, which is why this method will be called

   // Create a global variable, and assign it a
   // pointer to this enemy (the one that's loaded in the level bulder) 
   $enemy = %this;

   // Turn on debug, so we can see the trigger
   %sceneGraph.setDebugOn(5);

  // Create a trigger, notice the variable name we are assigning it to
  // "%this" is the enemy set up in the level builder, so 
  // we are assigning this enemy it's own trigger.  
  // This will allow us to move this enemy's trigger more easily.

     %this.triggerObject = new t2dTrigger() {
      canSaveDynamicFields = "1";
      sceneGraph = %sceneGraph;
      class = "enemyTrigger";
      Position = %this.position;
      size = "20 20";
      CollisionActiveSend = "1";
      CollisionActiveReceive = "1";
      CollisionCallback = "1";

   };

   // Ok, this is a bit goofy, but can be handy later
   // in english this is saying:
   // this enemy's trigger object has a field called parentObject, 
   // the value of which is a reference to this enemy. 
   %this.triggerObject.parentObject = %this;   

   // Let's make good use of our enemy object, and store it's speed
   // this is nice to do if you will have different enemies of varying speed
   // And we are making the enemy move via different functions, so this will
   // ensure it moves at a consistant velocity.
   %this.speed = 10;

   // Enable Update Callback on this enemy, 
   // so we can make the trigger move with the enemy 
   %this.enableUpdateCallback();

   // Bonus feature, we can make the enemy move back to it's original spot
   // after the player leaves it's range.  This is mainly to demonstrate
   // an example use of the trigger onLeave method.
   %this.originalPosition = %this.position;
}

function playerClass::onLevelLoaded(%this, %sceneGraph)
{
   // A player sprite was already configured in the level editor,
   // class was set to playerClass, which is why this method will be called   

   // a global reference to this player   
   $player = %this;

   // send collisions, and receive. 
   // send to your trigger, receive from the enemy. 
   // receiving is assumed because the enemy will probably be
   // able to collide with your player to damage it.
   %this.setCollisionActive(true, true); 
   %this.setCollisionCallback(true);

}

function enemyClass::onUpdate(%this)
{

   // Make the trigger move with the enemy, if necessary.
   // %this is referring to the enemy, not the trigger, but we can access 
   // the triggerObject stored within %this...
   %this.triggerObject.setPosition(%this.position);

}

function enemyTrigger::onEnter(%this, %object)
{
   // IMPORTANT!
   // %this = this trigger!
   // %object = the object which collided with the trigger

   // comment just for debugging purposes   
   echo("Something entered the trigger!");

   if (%object.class $="playerClass")
   {
      // comment just for debugging purposes       
      echo(" A PlayerClass object entered the trigger!");  

      // We don't have a reference to the enemy, Good thing
      // we made a global reference!   
      $enemy.moveTo(%object.getPosition(), $enemy.speed);

      // Here's an example of using a reference, if we did make one.
      // un Comment the line above to test this way.
      // %this.parentObject.moveTo(%object.getPosition(), %this.parentObject.speed);

   }
}

function enemyTrigger::onLeave(%this, %object)
{

   // comment just for debugging purposes       
   echo("Something just left the trigger!");    

   // IMPORTANT!!   
   // %this = this trigger, not this enemy
   // %object = the object that just left this trigger 
   // We don't have a reference to the enemy, Good thing
   // we made a global reference!
   $enemy.moveTo($enemy.originalPosition, $enemy.speed);  

   // or an example using the reference back to the parent object
   // uncomment the line above to test this way...
   //%this.parentObject.moveTo(%this.parentObject.originalPosition, %this.parentObject.speed);
}

function enemyClass::KillMe(%this) 
{
   // Kill this enemy's trigger first...
   %this.triggerObject.safeDelete();

   // Then kill this enemy!
   %this.safeDelete();
}

Game Development Community

trigger moving towards

About the author

Recent Threads