'Activate' World Objects

EDIT: This entire post was re-written on 01/15/2010 to make it more like a guide.

I've got this all working and thought I might share. Basically, this code uses a ray cast a short distance directly in front of the player and attempts to 'activate' objects the ray finds. This can be used to run ANY code on ANY object (such as talking to an NPC in an RPG game, opening doors, pulling levers, and more!) This code is the heart and soul of most of the interactive elements in my current project and I have no doubt I will use it again in many future projects.

(PS: This code has been tested and found working on TGE 1.5.2, TGEA 1.8.1, and T3D 1.0)

So here's a basic overview of what we need:

Activate.cs - The main script file that holds all of our activation code
game.cs (or scriptExec.cs for T3D) - We just need somewhere to execute our activate.cs file
default.bind.cs - The most common place to put your key bindings
Static Shape - You can use StaticShape, Item, or with some very small changes, any given $TypeMask you want (explained below)

Quote:
Important Note: I have a global variable for my main player called $player. I set this up in my player's 'spawn code'.

TGEA:
scriptsAndAssets/server/scripts/game.cs
T3D:
scripts/server/gameCore.cs AND core/scripts/server/spawn.cs

Look for where the %player is defined: %player =

Add below: $player = %player; //Now we can call on our player any time with any code with incredible ease -ND

Setup:

1. Create a new file called 'activate.cs'. Place it in your main scripts folder (next to game.cs or scriptExec.cs).

For TGEA: scriptsAndAssets/server/scripts/game.cs
For T3D: scripts/server/scriptExec.cs

2. Put the following code in your activate.cs file:

////////////////////////////////////////////////////////////
// Activate
////////////////////////////////////////////////////////////

function activate()
{
  //'Activate' can be used to activate AND deactivate objects that have already been activated.
  //First let's try to deactivate anything we might already have activated:
  //All of these 'deactivation' checks have a 'return;' on them to make sure the code stops until next time

    if($player.isCarrying){
      toggleCarryObject();
      return;
    }

    if($player.telekinesis)
    {
      toggleTelekinesis();
      return;
    }

    if($player.isBuilding)
    {
      toggleBuilding();
      return;
    }

    if($player.usingPC)
    {
      togglePC();
      return;
    }
    if($player.usingTeleporter)
    {
      toggleTeleporter();
      return;
    }

  //Now it's time to cast the ray in front of the player and search for 'activatable' objects

    // Check for 'activatable' objects in front of the player
    %distance = 1.64;    // Distance in front of eyePoint. Tweak this for 'how far to look in front of the player for activatable objects'
    %start = $player.getEyePoint();
    %vector = $player.getEyeVector();
    %vectorN = VectorNormalize(%vector);
    %vectorS = VectorScale(%vectorN,%distance);
    %end = VectorAdd(%vectorS,%start);

    %ray = ContainerRayCast(%start,%end,$TypeMasks::StaticShapeObjectType | $TypeMasks::ItemObjectType);

    if(%ray)
    {
       //ray collided with a staticshape. check to see if it is 'activatable'

       //A couple echoes to help with debugging
       echo("Ray: "@ %ray);
       %ray = getWord(%ray, 0);
       echo("Ray: "@ %ray);

       if(%ray.isCarryObject){
         toggleCarryObject(%ray);
       }

       //  Is the %ray a door?
       if(%ray.isDoor)
       {
           //Our ray found a door, run code to check for locks, keys, etc, then open door as needed, message the player, etc.
       }

       // Is the %ray a Lever?
       if(%ray.Lever)
       {
          //Our ray found a lever.  Run code to activate the lever
       }
  
       // Is the %ray a Buildable Object?
       if(%ray.isBuildable)
       {
         //Our ray found a 'buildable' object.  Run code to let the player build it, etc.
       }
  
       // Is the %ray a PC?
       if(%ray.isPC && !$player.usingPC)
       {
         togglePC();
       }

        // Is the %ray a Teleporter?
       else if(%ray.isTeleport && !$player.usingTeleporter)
       {
         toggleTeleporter();
       }
  
    }  //End if(%ray)
}

You will have to write your own code for each of the activatable objects. Sorry, but I just can't give everything away! :P

2. Ok so the next step is to make sure our file is executed. In game.cs or (scriptExec.cs for T3D), add the following line:

exec("./activate.cs");

And now your game has the 'activate' function.

3. Open your default.bind.cs:
TGE and TGEA: scriptsAndAssets/client/scripts/default.bind.cs
T3D: scripts/client/default.bind.cs

Somewhere near the top (or near your other key bindings), add the following:

moveMap.bind(keyboard,e,startActivate);             //Keyboard button E
moveMap.bind( joystick0, button4, startActivate);   //Playstation 2 style controllers, button X
moveMap.bind( gamepad, btn_x, startActivate);       //Xbox Controllers, button X

(You only need the ones you plan to use.)

And then anywhere in that same file (preferably under 'functions'), also add:

function startActivate(){
  if($startActivate){
    $startActivate=0;
    return;
  }
  else{
    $startActivate=1;
    activate();
  }
}

Which makes sure the code is only run once per button press. We could skip this part and just use 'bindCmd' above instead of just 'bind', but then we run into problems when remapping the buttons through the options menu within the game, and it also wouldn't be compatible with game controllers who, by nature, run functions every time the button is pressed, and again when released...

And voila!! You now have an 'activate' function that can be run any time you press the 'e' button on keyboard or 'x' on a controller!

One thing to make sure you do though!!

This code currently only looks for Static Shapes and Items. By changing or adding to the $TypeMasks, you can control what type of objects are checked for. In the activate.cs code, look for:

%ray = ContainerRayCast(%start,%end,$TypeMasks::StaticShapeObjectType | $TypeMasks::ItemObjectType);

IMPORTANT:
When the ray is actually cast, you NEED to have a dynamic field on each activatable object! In the code above, our ray will only tell us it found a door if the static shape we used for the door has the dynamic field:

isDoor = 1;

Then the ray will hit the door, see that %ray.isDoor, and thus run the 'door code'.

Any questions?