New Audio behaviours added.

if (!isObject(MouseClickSoundBehavior))
{
   %template = new BehaviorTemplate(MouseClickSoundBehavior);
   %template.friendlyName = "Mouse Click Sound";
   %template.behaviorType = "GUI";
   %template.description  = "Play a sound when the user clicks this object. ";
   %template.addBehaviorField(sound, "The sounds audio profile.", string ,"test"   );
   %template.addBehaviorField(useRightMouseButton, "Use right mouse button", bool, false);
} 

function MouseClickSoundBehavior::onBehaviorAdd(%this)
{ 
    %this.owner.setUseMouseEvents(true);  
}

function MouseClickSoundBehavior::onMouseUp(%this, %modifier, %worldPos)
{
    if(!%this.useRightMouseButton)
    {
        %this.playSound();
    }
}

function MouseClickSoundBehavior::onRightMouseUp(%this, %modifier, %worldPos)
{
    if(%this.useRightMouseButton)
    {
        %this.playSound();
    }
}

function MouseClickSoundBehavior::playSound(%this)
{
  if ( isobject(%this.sound) )
  {
     alxPlay( %this.sound );
  }
  else
  {
     echo( "MouseOverSoundBehavior: Invalid Audio Profile! " @  %this.sound );
  }
}