Override onDamage for local client only?

#1 Everything that you are doing is server side, and the effect you want needs to be client side.

However, your server does need to be the one to determine when a particular client should get a rumble, so you need to deliver a NetEvent to the appropriate client at "rumble time".

Fortunately, this is pretty easy. Script provides a set of commands designed specifically for this: commandToClient and clientCmd.

First, the syntax:

On the SERVER:

commandToClient(%clientToSendTo, 'TAG', <optional parameters>);

On the CLIENT:

function clientCmdTag(<optional parameters>)
{
  // do something here
}

Use case example:

SERVER:

commandToClient(%client, 'WiiRumble', %rumbleTime);

CLIENT:

function clientCmdWiiRumble( %rumbleTime)
{
   wiiRumble(%rumbleTime);
}

Now, on to figuring out which client to send to:

In the script method Armor::onDamage(%this, %obj, %delta), we have three parameters sent to us:

--%this : ObjectID of the datablock assigned to the player on the server
--%obj : ObjectID of the player object
--%delta : the damage to be done (from memory).

One more key element we need to know:

In /example/starter.fps/server/scripts/game.cs, we have the following callback that is performed on the server every time a client connects to the server:

function GameConnection::onClientEnterGame(%this)
{
   commandToClient(%this, 'SyncClock', $Sim::Time - $Game::StartTime);

   // Create a new camera object.
   %this.camera = new Camera() {
      dataBlock = Observer;
   };
   MissionCleanup.add( %this.camera );
   %this.camera.scopeToClient(%this);

   // Setup game parameters, the onConnect method currently starts
   // everyone with a 0 score.
   %this.score = 0;

   // Create a player object.
   %this.spawnPlayer();
}

This script does some important things for us, but for this particular need, I'm going to trace through the GameConnection::spawnPlayer() method, down to the GameConnection::createPlayer() method, which is the following:

function GameConnection::createPlayer(%this, %spawnPoint)
{
   if (%this.player > 0)  {
      // The client should not have a player currently
      // assigned.  Assigning a new one could result in 
      // a player ghost.
      error( "Attempting to create an angus ghost!" );
   }

   // Create the player object
   %player = new Player() {
      dataBlock = PlayerBody;
      client = %this;
   };
   MissionCleanup.add(%player);

   // Player setup...
   %player.setTransform(%spawnPoint);
   %player.setShapeName(%this.name);
   
   // Starting equipment
   %player.setInventory(Crossbow,1);
   %player.setInventory(CrossbowAmmo,10);
   %player.mountImage(CrossbowImage,0);

   // Update the camera to start with the player
   %this.camera.setTransform(%player.getEyeTransform());

   // Give the client control of the player
   %this.player = %player;
   %this.setControlObject(%player);
}

Lots of important stuff is done here, but the most critical part for us is the following:

// Create the player object
   %player = new Player() {
      dataBlock = PlayerBody;
      [b][i]client = %this;[/i][/b]
   };

Note that right now, %this is the objectID of the client that is connecting to the server right now.

The line within the new statement (italicized above) does something very important: it creates a dynamic field on the player object that contains the objectID of the client that the player object is assigned to.

Sound familiar? That's exactly what we need!

Given all the above, we need to implement the new function on the client ( clientCmdWiiRumble ), and our Armor::onDamage() should look like this:

function Armor::onDamage(%this, %obj, %delta)
{
   // This method is invoked by the ShapeBase code whenever the 
   // object's damage level changes.
   if (%delta > 0 && %obj.getState() !$= "Dead") {

      // Increment the flash based on the amount.
      %flash = %obj.getDamageFlash() + ((%delta / %this.maxDamage) * 2);
      if (%flash > 0.75)
         %flash = 0.75;
      %obj.setDamageFlash(%flash);

      // If the pain is excessive, let's hear about it.
      if (%delta > 10)
// change here
      {
         %obj.playPain();
         [b][i]commandToClient(%obj.client, 'WiiRumble', 1);[/i][/b]
      }
// end change
   }
}

This will properly deliver the wiiRumble event to the correct client in all cases.

#2 Stephen, thanks for taking the time to write such a clear explanation. I greatly appreciate it. I guess I was close -- I saw %this.client was the player, but I thought I could directly invoke some method from that object reference. It makes a lot more sense to think of it as integer datablock ID.

#3 Just a quick correction: %this.client does not exist in Armor::onDamage(). It should be %obj.client! %this is a datablock, NOT a player object.

Hopefully it works out for you!