Frustrum/Rendering question

//	Check if the bot can visually see the target
//	%previous means that it was a previous target (already seen)
//	hence has more chance of detection
function AIPlayer::checkLOStoTarget(%this, %obj, %previous)
{
   	%data = %this.getDataBlock();
   	%sightRange = %data.sightMaxRange;
   	%eyeTrans = %this.getEyeTransform();
   	%eyeEnd = %obj.getEyeTransform();
   	%searchResult = containerRayCast(%eyeTrans, %eyeEnd, $TypeMasks::PlayerObjectType | $TypeMasks::TerrainObjectType | $TypeMasks::InteriorObjectType, %this);
	%foundObject = getword(%searchResult,0);
	if(%foundObject.getType() & $TypeMasks::PlayerObjectType)
	{
		%dist = %this.checkDisttoTarget(%obj);
		%angle = %this.check2DAngletoTarget(%obj);

		if((%angle > %data.sightArcRange && %angle >= 0) || (%angle < 360-%data.sightArcRange && %angle > 180))
			return false;
		else if(%dist <= %data.sightMinRange)
			return true;
		else
		{
			%testperc = (%dist-%data.sightMinRange)/(%data.sightMaxRange-%data.sightMinRange);
			%diff = 1-%data.sightMaxAbility;
			%testval = (%testperc * %diff) + %data.sightMaxAbility;
			%testval = %previous ? %testval+0.30 : %testval;
			if(getRandom() <= %testval)
				return true;
			else
				return false;
		}
	}
	else
		return false;
}


//	Return distance to target
function AIPlayer::checkDisttoTarget(%this, %obj)
{
	%newdist = VectorDist(%obj.getPosition(), %this.getPosition());
	return %newdist;
}


//	Return vector to target
function AIPlayer::checkVectortoTarget(%this, %obj)
{
	%newVec = VectorSub(%obj.getPosition(), %this.getPosition());
	return %newVec;
}


//	Return the angle of a vector in relation to world origin
function AIPlayer::getAngleofVector(%this, %vec)
{
	%vector = VectorNormalize(%vec);
	%vecx = getWord(%vector,0);
	%vecy = getWord(%vector,1);
	if(%vecx >= 0 && %vecy >= 0)
		%quad = 1;
	else if(%vecx >= 0 && %vecy < 0)
		%quad = 2;
	else if(%vecx < 0 && %vecy < 0)
		%quad = 3;
	else
		%quad = 4;
	%angle = mATan(%vecy/%vecx, -1);
	%degangle = mRadToDeg(%angle);
	switch(%quad)
	{
		case 1:
			%angle = %degangle-90;
		case 2:
			%angle = %degangle+270;
		case 3:
			%angle = %degangle+90;
		case 4:
			%angle = %degangle+450;
	}
	return %degangle;
}



//	Return angle from bots eye vector to target
function AIPlayer::check2DAngletoTarget(%this, %obj)
{
	%eyeVec = VectorNormalize(%this.getEyeVector());
	%eyeangle = %this.getAngleofVector(%eyeVec);
	%posVec = VectorSub(%obj.getPosition(), %this.getPosition());
	%posangle = %this.getAngleofVector(%posVec);
	%angle = %posangle - %eyeAngle;
	%angle = %angle ? %angle : %angle * -1;
	return %angle;
}