wheel mouse for switching weapons

by Ace · in Torque Game Engine · 01/19/2002 (6:09 am) · 22 replies · expect

function handleMouseWheel(%val)
{
 if( %val )
  commandToServer( 'NextWeapon' );
 else
  commandToServer( 'PrevWeapon' );
}

moveMap.bind( mouse, zaxis, handleMouseWheel );
moveMap.bind(mouse0, "zaxis", handleMouseWheel);
//------------------------------------------------------------------------------
// Mouse Wheel
//------------------------------------------------------------------------------

function handleMouseWheel(%val)
{
   // Check if the wheel scrolled up or down
   if( %val > 0 )
   {
      commandToServer( 'NextWeapon' );
   }
   else
   {
      commandToServer( 'PrevWeapon' );
   }
}

moveMap.bind( mouse, zaxis, handleMouseWheel );
// NextWeapon selects the first available Next weapon
function serverCmdNextWeapon(%client)
{
   echo( "<< DEBUG >> serverCmdNextWeapon 2" );
   // Add the weapon select code
}

// PrevWeapon selects the first available Previous weapon
function serverCmdPrevWeapon(%client)
{
   echo( "<< DEBUG >> serverCmdPrevWeapon 2" );
   // Add the weapon select code
}
// NextWeapon selects the first available Next weapon
function serverCmdNextWeapon(%client)
{
   // Select the player object
   %player = %client.getControlObject();

   // ToDo: There should be a check here, to see if this is indeed a player object!

   // Store the current selected weapon, so we know when we've cycled thru all weapons
   %currentWeapon = %player.getInvItem( "current", "name" );

   // Select the next item in the inventory
   while( %player.moveCurPtr( "next" ) == 1 )
   {
      // Check if this is the weapon we started with
      if( %player.getInvItem( "current", "name" ) $= %currentWeapon )
      {
         // Abort
         return 0;
      }
      // Check if this is a weapon
      else if( %player.getInvItem( "current", "type" ) $= "weapon" )
      {
         // Check if the weapon is present!
         if( %player.getInvItem( "current", "amount" ) > 0 )
         {
            // Use the weapon
            %client.getControlObject().use( %player.getInvItem( "current", "name" ) );
            // Done!
            return 1;
         }
      }
      else
      {
         // This is not a weapon anymore, select the first inv. item (must be a weapon)
         if( %player.moveCurPtr( "first" ) == 0 )
         {
            // This should always work, if not, log an error
            echo( "ERROR - WeaponSelect could not select inv. slot 0" );
            // Abort
            return 0;
         }
      }
   }
}
// NextWeapon selects the first available Next weapon
function serverCmdNextWeapon( %client )
{
   // Select the player object
   %player = %client.getControlObject();

   // ToDo: There should be a check here, to see if this is indeed a player object!

   // Store the current selected weapon, so we know when we've cycled thru all weapons
   %currentWeapon = %player.getInvItem( "current", "name" );
   // Select the next item in the inventory
   if( %player.moveCurPtr( "next" ) != 1 )
   {
      // Selecting the next item failed, select the first item instead!
      if( %player.moveCurPtr( "first" ) == 0 )
      {
         // This should always work, if not, log an error
         echo( "ERROR - WeaponSelect could not select the first inv. slot" );
         // Abort
         return 0;
      }
   }

   // Check if this is the weapon we started with
   while( %player.getInvItem( "current", "name" ) !$= %currentWeapon )
   {
      // Check if this is a weapon
      if( %player.getInvItem( "current", "type" ) $= "weapon" )
      {
         // Check if the weapon is present!
         if( %player.getInvItem( "current", "amount" ) > 0 )
         {
            // Use the weapon
            %client.getControlObject().use( %player.getInvItem( "current", "name" ) );
            // Done!
            return 1;
         }
      }
      else
      {
         // This is not a weapon anymore, select the first inv. item (must be a weapon)
         if( %player.moveCurPtr( "first" ) == 0 )
         {
            // This should always work, if not, log an error
            echo( "ERROR - WeaponSelect could not select the first inv. slot" );
            // Abort
            return 0;
         }
      }

      // Select the next item in the inventory
      if( %player.moveCurPtr( "next" ) != 1 )
      {
         // Selecting the next item failed, select the first item instead!
         if( %player.moveCurPtr( "first" ) == 0 )
         {
            // This should always work, if not, log an error
            echo( "ERROR - WeaponSelect could not select the first inv. slot" );
            // Abort
            return 0;
         }
      }
   }
}
///////////////////////////////////////////////////////////////
//  move the currentpos pointer next, last, or first
///////////////////////////////////////////////////////////////
bool Inventory::MoveCurrent(char* move) {

	if (dStricmp(move, "next") == 0) {

		return NextLink();

	} else if (dStricmp(move, "last") == 0) {

	    return LastLink();

	} else if (dStricmp(move, "first") == 0) {

        CurrentItemInList = FirstItemInList;
		if (CurrentItemInList != NULL)
		    return true;
		else
		    return false;

	}

	return false;
}
function serverCmdNextWeapon(%client, %data)
{
   %client.getControlObject().nextWeapon();
}

function serverCmdPrevWeapon(%client, %data)
{
   %client.getControlObject().prevWeapon();
}

function ShapeBase::prevWeapon(%this)
{
	%fromEnd = true;
	%currentWeapon = "";
	while ( %this.moveCurPtr("next") == true ) {}	// Point at the last item in the inv list.

	// Check if there is a weapon in use.
	if ( (%image = %this.getMountedImage($WeaponSlot)) != 0 )
	{
		// There is a weapon in use. Find it and point at the first item before it.
		%currentWeapon = %image.item.getName();
		while ( %this.getInvItem("current", "name") !$= %currentWeapon )	// Note: No error checks in this loop.
			%this.moveCurPtr("last");

		if ( %this.moveCurPtr("last") == false )
			while ( %this.moveCurPtr("next") == true ) {}	// The current weapon was the first item in the list, restart.
		else
			%fromEnd = false;
	}

	// Iterate through the list.
	while ( true )
	{
		if ( %this.getInvItem("current", "type") $= "weapon" )
		{
			%weapon = %this.getInvItem("current", "name");
			if ( %weapon $= %currentWeapon )
				return;		// No other weapons found.
			else if ( %this.getInvItem("current", "amount") > 0 )
			{
				// Weapon found, use it.
				%weapon.onUse(%this);
				return;
			}
		}

		if ( %this.moveCurPtr("last") == false )
		{
			// End of list.
			// If all of the list was searched, return. Otherwise restart from the beginning of the list.
			if ( %fromEnd == true )
				return;
			%fromEnd = true;
			while ( %this.moveCurPtr("next") == true ) {}
		}
	}
}

function ShapeBase::nextWeapon(%this)
{
	%fromBeg = true;
	%currentWeapon = "";
	%this.moveCurPtr("first");

	// Check if there is a weapon in use.
	if ( (%image = %this.getMountedImage($WeaponSlot)) != 0 )
	{
		// There is a weapon in use. Find it and point at the first item after it.
		%currentWeapon = %image.item.getName();
		while ( %this.getInvItem("current", "name") !$= %currentWeapon )	// Note: No error checks in this loop.
			%this.moveCurPtr("next");

		if ( %this.moveCurPtr("next") == false )
			%this.moveCurPtr("first");	// The current weapon was the last item in the list, restart.
		else
			%fromBeg = false;
	}

	// Iterate through the list.
	while ( true )
	{
		if ( %this.getInvItem("current", "type") $= "weapon" )
		{
			%weapon = %this.getInvItem("current", "name");
			if ( %weapon $= %currentWeapon )
				return;		// No other weapons found.
			else if ( %this.getInvItem("current", "amount") > 0 )
			{
				// Weapon found, use it.
				%weapon.onUse(%this);
				return;
			}
		}

		if ( %this.moveCurPtr("next") == false )
		{
			// End of list.
			// If all of the list was searched, return. Otherwise restart from the beginning of the list.
			if ( %fromBeg == true )
				return;
			%fromBeg = true;
			%this.moveCurPtr("first");
		}
	}
}

Game Development Community

wheel mouse for switching weapons

About the author

Recent Threads