Serpent - In progress

// --------------------------------------------------------------------
// Handle when the player has been killed and reset the player
// --------------------------------------------------------------------
function KillPlayer()
{
	// Disable keyboard input
	playerMap.pop();

	// Ensure that the player does not keep calling world limit callback
	$player.setWorldLimit( clamp, "-400 -300 400 300");

	// Ensure that the player does not keep calling collision callback
	$player.setCollisionActive( false, false );

	// Stop the serpents head
	$player.setAtRest();

	// Stop the serpents body
	for(%a=$tailSize; %a >= 0; %a--) 
               {
		$body[%a].dismount();
		$body[%a].setAtRest();
               }

	// Shake that screen!
	SceneWindow2D.startCameraShake( 50, 5);

	// Set high score
	if($playerScore > $highScore)
	{
		$highScore = $playerScore;
	}

	schedule( 5000, 0, "exitGame");
}

// --------------------------------------------------------------------
// Return to main menu after death or escape is pressed.
// --------------------------------------------------------------------
function exitGame()
{
	// Free up memory used in that game session
	freeGameMemory();

	// Set GUI.
	Canvas.setContent( serpentMainGui );	
}

// --------------------------------------------------------------------
// Free system memory
// --------------------------------------------------------------------
function freeGameMemory()
{
	// Delete the serpents head
	$player.safeDelete();

	// Delete the serpents body
	for(%a=$tailSize; %a >= 0; %a--) 
	{
		$body[%a].safeDelete();
	}

	// Delete any food
	$food.safeDelete();
}

//-----------------------------------------------------------------------------
// Handles increasing the size of the serpent
//-----------------------------------------------------------------------------
function playerSizeUp()
{
	// Increase the size of the serpent
	$tailSize += 1;
	
	// Create new body part
	$body[$tailSize] =  new fxStaticSprite2D() { scenegraph = serpentSceneGraph; };
	$body[$tailSize].setPosition( $body[$tailSize-1].getPosition() );
	$body[$tailSize].setLayer( 2 );
	$body[$tailSize].setSize( "32 32" );
	$body[$tailSize].setImageMap( snakeBodyImageMap );
	$body[$tailSize].tag = "tail";

                
	// Set up collision model for tail part
	$body[$tailSize].setGroup( 2 );
	$body[$tailSize].setCollisionScale( "0.5 0.5" );
	$body[$tailSize].setCollisionActive( false, true );
 
                
   // Mount extra part of serpent to player
	$body[$tailSize].mount($body[$tailSize-1], "0.0 0.0", 16, false, false, false, false);
}