Throwing Objects!

moveMap.bindCmd(keyboard, "q", "commandToServer(\'throw\',0);", "");

function ItemData::onThrow(%this,%user,%amount)
{
   %obj = new Item() {
      datablock = %this;
      rotation = "0 0 1 " @ (getRandom() * 360);
      count = %amount;
   };
   MissionGroup.add(%obj);
   %obj.schedulePop();
   return %obj;
}

function ShapeBaseData::onThrow(%this,%user,%amount) { return 0; }

function serverCmdThrow(%client,%data)
{
   %client.getControlObject().throw(%data);
}

// Player's throw function
function ShapeBase::throw(%this,%slot)
{
   //itemName being the object I want to create
   %inv = %this.InventoryManager;
   %db = %inv.Slot[%Slot].itemName;   

   if ( %db $= "")
      return 0; 

   %obj = %db.onThrow(%this, 1);    

   if (%obj) 
   {
      %this.throwObject(%obj);
      return true;
   }

   return false; 
}

function ShapeBase::throwObject(%this,%obj)
{
   %throwForce = %this.throwForce;
   if (!%throwForce)
      %throwForce = 20;

   %eye = %this.getEyeVector();
   %vec = vectorScale(%eye, %throwForce);

   %verticalForce = %throwForce / 2;
   %dot = vectorDot("0 0 1",%eye);
   if (%dot < 0)
      %dot = -%dot;
   %vec = vectorAdd(%vec,vectorScale("0 0 " @ %verticalForce,1 - %dot));

   %vec = vectorAdd(%vec,%this.getVelocity());

   %pos = getBoxCenter(%this.getWorldBox());
   %obj.setTransform(%pos);
   %obj.applyImpulse(%pos,%vec);

   %obj.setCollisionTimeout(%this);
}