Swap to a normal camera in the RTS editor

My partner in crime on this project, Ralph "ZOD" DeMicco was a tad bit disgusted with having the RTSCamera in the editor, so he scripted up a way to get the normal torque editor camera in, here it is:

In file common/editor/EditorGui.cs change existing functions to these..

function EditorGui::onWake(%this)
{
   //------------------------------------------------------------------
   // Because the RTS camera is impossible to work with in the editor,
   // we swap it for a standard camera here. We delete all RTS objects.
   // Have to use the client ID the server assigns or this = poop
   // We capture this ID via a message callback and store it in a global.
   %client = $Client::MyClient;
   %transform = %client.camera.getTransForm();
   %client.camera.setVelocity("0 0 0");

   %client.camera = new Camera() {
      dataBlock = Observer;
   };
   MissionCleanup.add(%client.camera);
   %client.camera.scopeToClient(%client);
   %client.camera.getDataBlock().setMode(%client.camera, "Editor");
   %client.camera.setTransform(%transform);
   %client.setControlObject(%client.camera);
   //------------------------------------------------------------------

   MoveMap.push();
   EditorMap.push();

   %this.setEditor(%this.currentEditor);
}

function EditorGui::onSleep(%this)
{
   error("EditorGui::onSleep(" SPC %this.getName() SPC ")");
   //------------------------------------------------------------------
   // Now we have to swap back to the RTS camera here. We delete the
   // standard camera and the game handles the rest. Have to use the
   // client ID the server assigns or this = poop
   // We capture this ID via a message callback and store it in a global.
   %client = $Client::MyClient;
   if (isObject(%client.camera))
      %client.camera.delete();

   %client.camera = new RTSCamera()
   {
      dataBlock = RTSObserver;
   };
   MissionCleanup.add( %client.camera );

   // Do scoping
   %client.camera.scopeToClient(%client);

   %client.setControlObject(%client.camera);
   //------------------------------------------------------------------

   %this.setPrefs();
   EditorMap.pop();
   MoveMap.pop();
}

In file common/server/gameConnection.cs
Must add this message to function GameConnection::onConnect somewhere after all the jojn messages

// Send this player their client ID etc.
   messageClient(%client, 'MsgYourInfo', "", %client.name, %client);

In file starter.RTS/client/scripts/serverConnection.cs
At the top of the function function RTSConnection::initialControlSet(%this),
add the following lines..

if(isObject(EditorGui))
   {
      if (Canvas.getContent() == EditorGui.getId())
         return;
   }

Then someplace in starter.RTS/client/scripts/missionDownload.cs
add these callback handlers..

addMessageCallback( 'MsgYourInfo', handleGetMyInfo );

function handleGetMyInfo(%msgType, %msgString, %clientName, %clientId)
{
   $Client::MyClient = %clientId;
}