Trouble creating a trigger by script and getting callbacks

// create a building as indicated by the %type at the point we clicked.  Right
// now this only creates a "Barracks" building.
function serverCmdcreateBuilding(%client, %pos, %start, %ray, %type)
{
    // find end of search vector
    %ray = VectorScale(%ray, 2000);
    %end = VectorAdd(%start, %ray);

    %searchMasks = $TypeMasks::TerrainObjectType;

    // search!
    %scanTarg = ContainerRayCast( %start, %end, %searchMasks);

    // If the terrain object was found in the scan
    if( %scanTarg )
    {
        %obj = getWord(%scanTarg, 0);

        %pos = getWords(%scanTarg, 1, 3);

        // spawn a new object at the intersection point
        %obj = new TSStatic()
        {
            position = %pos;
            shapeName = "art/shapes/building/orcburrow.dts";
            class = "barracks";
            collisionType = "Visible Mesh";
            scale = "0.5 0.5 0.5";
        };
        %obj.team = %client.getId();

        // Add the new object to the MissionCleanup group
        MissionCleanup.add(%obj);
        
        // Set up a spawn point for new troops to arrive at.
        %teamSpawnGroup = "Team"@%client.team@"SpawnGroup";
        if (!isObject(%teamSpawnGroup))
        {
            new SimGroup(%teamSpawnGroup)
            {
                canSave = "1";
                canSaveDynamicFields = "1";
                    enabled = "1";
            };

            MissionGroup.add(%teamSpawnGroup);
        }
        
        %spawnName = "team"@%client.team@"Spawn" @ %obj.getId();
        %datablock = (%type !$= "" ? %type : $Game::DefaultPlayerDataBlock);
        %point = new SpawnSphere(%spawnName)
        {
            radius = "1";
            dataBlock      = "SpawnSphereMarker";
            spawnClass     = $Game::DefaultPlayerClass;
            spawnDatablock = %datablock;
        };
        %point.position = VectorAdd(%obj.getPosition(), "0 6 2");
        %obj.spawnPoint = %point;
        %teamSpawnGroup.add(%point);
        MissionCleanup.add(%point);

        %triggerName = "team"@%client.team@"Trigger" @ %obj.getId();
        %box = %obj.getWorldBox();
        %rot = %obj.rotation;
        %pos = %obj.getPosition();
        %scalex = (getWord(%box, 3) - getWord(%box, 0)) * 1.2;
        %scaley = (getWord(%box, 4) - getWord(%box, 1)) * 1.2;
        %scalez = (getWord(%box, 5) - getWord(%box, 2)) * 10.0;
        %scale = %scalex SPC %scaley SPC %scalez;
        %trigger = new Trigger(%triggerName)
        {
            polyhedron = "-0.5 0.5 0.0 1.0 0.0 0.0 0.0 -1.0 0.0 0.0 0.0 1.0";
            dataBlock = "BarracksTrigger";
        	rotation = %rot;
        	position = %pos;
        	scale = %scale;
        };
        %trigger.owner = %obj;
        MissionCleanup.add(%trigger);
    }
}