AI Weirdness

by Robert Fritzen · in Torque 3D Professional · 04/10/2012 (4:02 pm) · 20 replies · 04/11/2012 (8:48 am)

function spawnZombie(%number, %position) {
   if(%number == 1) {
      %block = "ZombiePlayerData";
   }
   else if(%number == 6) {
      %block = "MegaZombiePlayerData";
   }
   else {
      %block = "Zombie0"@%number@"PlayerData";
   }

   if(%number < 1 || %number > 6) {
      %block = "ZombiePlayerData";
   }

   //create a new path for this Ai's personal use
   %path = createNewPath();

   // Create the demo player object
   %player = new AiPlayer() {
      dataBlock = %block;
      position = %position;
      path = %path;
   };
   MissionCleanup.add(%player);
   //%player.path = %path;

   %player.setTransform(%position);

   //this is an arrayObject in my gameClass
   game.zombieGroup.add(%player, %path);

   //are we stuck?
   %player.stuck = 0;

   //movement nodes
   %player.currentNode = 0;
   %player.targetNode = 0;

   //pause a moment to let behind the scene stuff work out
   %player.schedule(1000, "aiStartUp");

   return %player;
}

function AIPlayer::getNearestTarget(%this) {
   %targ = -1;
   %closest = 99999;
   for(%i = 0; %i < ClientGroup.getCount(); %i++) {
      %cl = ClientGroup.getObject(%i);
      if(isObject(%cl.player) && %cl.player.getState() !$= "dead") {
         %d = vectorDist(getWords(%this.getTransform(), 0, 2), getWords(%cl.player.getTransform(), 0, 2));
         if(%d < %closest) {
            %targ = %cl.player;
            %closest = %d;
         }
      }
   }
   return %targ;
}

function AIPlayer::aiStartUp(%this) {
   if(!isObject(%this)) {
      return;
   }

   if(%this.getState() $= "Dead") {
      return;
   }

   %path = %this.path;

   %this.setMoveSpeed(0.5);

   //get an initial path
   %start = %this.getPosition();

   %enemy = %this.getNearestTarget();
   //echo("Startup: ENEMY: "@%enemy);
   if(!isObject(%enemy)) {
      %end = "0 0 0";
   }
   else {
      %end = %enemy.getPosition();
   }

   //create the variables for the path
   %this.path.from = %start;//add variable
   %this.path.to = %end;//add variable

   %path.plan();
   %this.canWeHit();
   %this.followPath(%path, -1);
}

function AIPlayer::canWeHit(%this) {
   if(!isObject(%this) || %this.getState() $= "dead") {
      return;
   }
   %path = %this.path;
   %target = %this.getNearestTarget();
   if(isObject(%target)) {
      //give it one more distance than the actual datablock
      if(%this.playerLOS(%target, 3)) {
         //fire
         %this.aimAt(%target);
         Melee_Attack(%this);
      }
      %this.path.from = %this.getPosition();
      %this.path.to = %target.getPosition();
      %path.plan();

      %this.followPath(%path, -1);
   }
   %this.schedule(500, canWeHit);
}

function Player::getPosition(%this) {
   return getWords(%this.getTransform(), 0, 2);
}

function ZombiePlayerData::onMoveStuck(%this, %obj) {
       //echo( %obj @ " onMoveStuck" );

   if(%obj.stuck > 20) {
      %obj.stop();
      %obj.randomPath();
   }
   else {
      %obj.stuck++;
   }
}

function ZombiePlayerData::onEndOfPath(%this,%obj,%path) {
   %obj.aiDecide();
}

function ZombiePlayerData::onDamage(%this, %obj, %delta) {
   if(%obj.getstate() $= "Dead") {
      //take finger off trigger
      %obj.setImageTrigger(0, 0);
      //cleanup
      %path = %this.path;
      %index = game.zombieGroup.getIndexFromKey(%obj);
      if(%index != -1) {
         game.zombieGroup.erase(%index);
      }

      //delete the Ai's path
      if(isObject(%path)) {
         if(%path.getClassname() $="navPath") {
            %path.delete();
         }
      }
      //
      %src = %obj.lastDamageBy;
      echo("dead by: "@%src@" "@%src.client);
      if(%src.client !$= "") {
         commandToClient(%src.client, 'UpdateInformation', 'points', 10); //10 points for a zombie kill!
      }
      //
      game.zombieCount--;
      game.checkNextWave();
   }
}

function AIPlayer::aiDecide(%this) {
   if(!isObject(%this) || %this.getState() $= "dead") {
      return;
   }
   %path = %this.path;//temporary alias for our path
   %start = %this.getPosition();

   //find that player!
   %enemy = %this.getNearestTarget();
   if(isObject(%enemy)) {
      if(%enemy.getState() !$= "Dead") {
         %end = %enemy.getPosition();
         %path.from = %start;
         %path.to = %end;
         %path.plan();

         %this.followPath(%path, -1);//hunt!
         return;
      }
   }
   //randomPath
   %this.randomPath();
}

function AIPlayer::randomPath(%this) {
   if(!isObject(%this) || %this.getState() $= "dead") {
      return;
   }

   %this.stuck = 0;
   %this.currentNode = 0;
   %this.targetNode = 0;

   %start = %this.getPosition();

   //get a random goal, count available up
   %count = ZombieDropPoints.getCount();

   //get the max. index from the group.
   //Index starts at 0 and not 1.
   //so we need to take 1 off the count
   %max = %count - 1;

   //randomize!
   %index = getRandom(0, %max);

   //get the spawnSphere from the simgroup at the index
   %spawn = ZombieDropPoints.getObject(%index);
   %end = %spawn.getPosition();

   NavPath1.from = %start;
   NavPath1.to = %end;
   NavPath1.plan();

   %this.followPath(NavPath1, -1);
}

function AIPlayer::playerLOS(%this, %them, %dist) {
   if(!isObject(%this) || !isObject(%them)) {
      return false;
   }
   //from our eye to the player's eye
   %ai = %this.getEyePoint();
   %player = %them.getEyePoint();

   //things to get in the way
   %mask = $TypeMasks::TerrainObjectType | $TypeMasks::StaticObjectType;

   // see if anything gets hit
   %collision = containerRayCast(%ai, %player, %mask, %this);

   //nothing hit, this happens when EyeNode is outside of boundsBox
   //and thus raycast has no collision to record against
   //still means that they are viewable
   if(!%collision) {
      if(vectorDist(%ai, %player) <= %dist) {
         return true;
      }
      else {
         return false;
      }
   }

   %hit = firstWord(%collision);
   //we can see them
   if(%hit == %them) {
      if(vectorDist(%ai, %player) <= %dist) {
         return true;
      }
      else {
         return false;
      }
   }
   else {
      return false;
   }
}

//Navegation Interfacing
function createNewPath() {
   %path = new NavPath() {
      from = "0 1 1";
      to = "10 1 1";
      mesh = "Nav";
   };
   MissionCleanup.add(%path);
   return %path;
}

function ZombiePlayerData::onReachDestination(%this,%obj)
{
   //echo( %obj @ " onReachDestination" );

   // Moves to the next node on the path.
   // Override for all player.  Normally we'd override this for only
   // a specific player datablock or class of players.
   if (%obj.path !$= "")
   {
      if (%obj.currentNode == %obj.targetNode)
         %this.onEndOfPath(%obj,%obj.path);
      else
         %obj.moveToNextNode();
   }
}

function ZombiePlayerData::onTargetExitLOS(%this,%obj)
{
   //echo( %obj @ " onTargetExitLOS" );
}

function ZombiePlayerData::onTargetEnterLOS(%this,%obj)
{
   //echo( %obj @ " onTargetEnterLOS" );
}
function ZombiePlayerData::onEndSequence(%this,%obj,%slot)
{
   echo("Sequence Done!");
   %obj.stopThread(%slot);
   %obj.nextTask();
}

Game Development Community

AI Weirdness

About the author

Recent Threads