Problem with platformer wall collision when jumping

#1 I know I've solved your second problem, but I'm not entirely sure what you mean by the first one. More because I don't remember running into that problem.

Anyway, the only change I did to the updateVertical function is in the "no collision" block.

You have the following:

// no collision  
   if (%collision $= "")  
   {  
      %this.airborne = true;  
      %this.setConstantForceY(100);  
      %this.setLinearVelocityY(%yVelocity);  
      return;  
   }

Mine is this:

// no collision  
   if (%collision $= "")  
   {  
      %this.againstLeftWall = false;
      %this.againstRightWall = false;
      %this.airborne = true;  
      %this.setConstantForceY(100);  
      %this.setLinearVelocityY(%yVelocity);  
      return;  
   }

I compared our functions and that was the only change in that function. I'm not sure if I have something different in my updateHorizontal function. I'll post it here for you though.

function Player::updateHorizontal(%this)
{
  if(%this.moveLeft == %this.moveRight)
  {
    %this.setLinearVelocityX(0);
    return;
  }
  if(%this.moveLeft)
  {
    if(!%this.againstLeftWall)
    {
      %this.againstRightWall = false;
      %this.setLinearVelocityX(-90);
    }
  }
  if(%this.moveRight)
  {
    if(!%this.againstRightWall)
    {
      %this.againstLeftWall = false;
      %this.setLinearVelocityX(90);
    }
  }
}

If you see anything different between yours and mine let me know, cause my curiosity is piqued.

#2 Thanks for the reply. I hadn't touched my code since you posted, but I tried what you did for no collision and it seems to have worked. Thinking back, I didn't always have the first problem (since I recall distinctly trying to solve the second problem independent of it).

My code for my character is fairly complex and convoluted based on my game design (character can change to 6 different colours and either sticks to, is repelled by, passes through or collides normally with objects of different colours depending on what colour the character is). I put the basic tutorial code in my original post to avoid having too many variables nobody would have any frame of reference for. Anyway, here's the updates horizontal and vertical with some other stuff to make it make sense.

function playerClass::updateHorizontal(%this)
{
	if($player.getLinearVelocityX() < 2)
	{
		if($player.getLinearVelocityX() > -2)
		{
			$player.setLinearVelocityX(0);
		}
	}
	if(!%this.airborne)
	{
		if(%this.moveLeft == %this.moveRight)
		{
			$player.setLinearVelocityX(0);
		}
	}
		
	if (%this.moveLeft)
	{
		if (!%this.moveRight)
		{
      		if (!%this.againstLeftWall)
      		{
				%this.againstRightWall = true;
				if(%this.control)
				{
					%this.setLinearVelocityX(%this.xMoveLeft);
				}
			}
      	}
	}
	if (%this.moveRight)
	{
		if (!%this.moveLeft)
		{
			if (!%this.againstRightWall)
			{
				%this.againstLeftWall = true;
				if(%this.control)
				{	
					%this.setLinearVelocityX(%this.xMoveRight);
				}
			}
		}
	}
	if (%this.moveUp)
	{
		if (!%this.airborne)
		{
			%this.setLinearVelocityY(-20);
		}
	}
	if (%this.moveDown)
	{
		if (!%this.airborne)
		{
			%this.setLinearVelocityY(20);
		}
	}
	if(!%this.airborne)
	{
		if($inStick)
		{
			if(!%this.airborne)
			{
				if(%this.moveUp == %this.moveDown)
				{
					$player.setLinearVelocityY(0);
				}
			}
		}
	}
}
function playerClass::updateVertical(%this)
{
	%xVelocity = %this.getLinearVelocityX();
	%yVelocity = %this.getLinearVelocityY();

	%this.setLinearVelocityY(5);
	%collision = %this.castCollision(0.004);  
	
	%normalX = getWord(%collision, 4);
	%normalY = getWord(%collision, 5);

//no collision
	if (%normalX == 0 && %normalY == 0)
   	{
		%this.airborne = %this.noColAir;
		%this.againstLeftWall = false;
		%this.againstRightWall = false;
      	%this.setConstantForceY(%this.noColConY);
		%this.setLinearVelocityY(%yVelocity);
		%this.setLinearVelocityX(%xVelocity);
      	return;
   	}
	
// collides with wall to the left
   	if (%normalX == 1 && %normalY == 0)
   	{

     	%this.againstLeftWall = true;
		%this.setLinearVelocityX(%this.xLeft);   					
		%this.setLinearVelocityY(%this.leftY);
      	return;
	}   
	
// collides with wall to the right
   	if (%normalX == -1 && %normalY == 0)
   	{
      	%this.againstRightWall = true;
      	%this.setLinearVelocityX(%this.xRight);
		%this.setLinearVelocityY(%this.rightY);
		return;
   	}
	
// on ground with no wall collisions
   	if (%normalX == 0 && %normalY == -1)
   	{
      	%this.airborne = %this.bottomAir;
      	%this.againstLeftWall = false;
      	%this.againstRightWall = false;
      	%this.setConstantForceY(%this.bottomConY);
      	%this.setLinearVelocityY(%this.bottomY);
      	return;
   	}
	
// in air and hits platform with head
   	if (%normalX == 0 && %normalY == 1)
   	{
			
		%this.airborne = %this.topAir;
      	%this.setLinearVelocityX(0);
      	%this.setConstantForceY(%this.topConY);
      	%this.setLinearVelocityY(%this.topY);
      	return;
   	}
	
}
function playerClass::onUpdate(%this)
{
	%this.updateHorizontal();
	%this.updateVertical();
	%this.onCollision();
	%this.setCurrentAnimation();
	%this.controlTimer();
	%this.resetThings();
}
function playerClass::controlTimer(%this)
{
	if(!$player.control)
	{
		%this.schedule(250, "returnControl");
	}
}
function playerClass::returnControl(%this)
{
	%this.control = true;
}
function playerClass::resetThings(%this)
{
	if(%this.control)
	{
		%this.xLeft = 0;
		%this.xRight = 0;
	}
}

The control function is used to take control from the player for a moment when they repel off an object, to prevent the user from just mashing up against it.

#3 Ok, so I commented out my slightly more convoluted onUpdateHorizontal and replaced it with the one you posted and I still see the same issue. Since fixing the second issue it now occurs 100% of the time... the best way I can describe it is that the character seems to "hug" walls if you press against them. Basically stops if you're moving up or slows down if you're moving down. I want it to ignore the wall completely until it clears it.

I've been messing with this a lot, and turning off my moveRight/moveLeft functions in my onUpdateVertical when the character is touching the respective walls provides me with a slightly better result than where I started (no rubbing/hugging on walls, but once the character makes it above the wall it won't keep moving in that direction unless I release the directional key and press it again). I'm trying to wrap my head around other possible solutions, since this one feels hacky and doesn't quite work. For some reason using againstRightWall/againstLeftWall being false as a condition for moving in the respective direction doesn't help at all.

#4 Ok, doesn't seem like anyone is following this thread but just in case someone runs into the same problem one day...

Basically, the variables being called in the collision functions were being set when the character actually touched the object, not when the cast collision detected the object. That was screwing things up. If I replace the variables with static numbers that fixes this issue, but causes others. What I'm going to do now is use triggers to set the variables appropriately before the character detects the object.

I really doubt this will come up for anyone else unless you have conditional collision variables like me, but you never know...

#5 Adam, I'm having a similar problem, and I'm interested to see how you've perfected your platforming movement.

Basically, when you hold left or right against a wall and press jump, the player jumps higher than normal/expected. This happens specifically whn adding in the code:

// no collision
  if(%collision $= "")
  {
    %this.againstleftWall = false;
    %this.againstRightWall = false;
    %this.inAir = true;
    %this.setConstantForceY($gravity);
    %this.setLinearVelocityY(%tempY);
    return;
  }

If I leave out:

%this.againstleftWall = false;
%this.againstRightWall = false;

it will stop at the correct jump height but will not continue moving in the direction being held down.

Any ideas?

-Drew

[]I own TGB on another account, which can be verified.[]