how do i save variables to a file and load them on startup ?[solved]

#1 This seems to work very well ...

$ScoreBoard::isLoaded = false;
function LoadScores()
{
   %loadFile = new FileObject();
   %dataFile = expandFilename("scripts/gui/scoreboard.txt");
   
   %loadFile.openForAppend(%dataFile);
   %loadFile.close();
   
   %loadFile.openForRead(%dataFile);

   // read in 5 scores
   for (%count=0; %count < $ScoreBoard::Count; %count++)
   {     
      $ScoreBoard::Scores[%count] = %loadFile.readLine();
      $ScoreBoard::Names[%count] = %loadFile.readLine();
      $ScoreBoard::Mission[%count] = %loadFile.readLine();      
   }   
   
   %loadFile.close();
   %loadFile.delete(); // object not file it self
   
   $ScoreBoard::isLoaded = true;
}

function SaveScores()
{
	%saveFile = new FileObject();

	%dataFile = expandFilename("scripts/gui/scoreboard.txt");	
	%saveFile.openForWrite(%dataFile);

   for (%count=0; %count < $ScoreBoard::Count; %count++)
   {     
      %saveFile.writeLine( $ScoreBoard::Scores[%count] );
      %saveFile.writeLine( $ScoreBoard::Names[%count] );
      %saveFile.writeLine( $ScoreBoard::Mission[%count] );      
   }   
	
	%saveFile.close();
	%saveFile.delete();  // delete %saveFile object, not file itself      
}

// Use this to add a new Top Score ... it will drop the last one
// and replace it with this score
function AddScoreBoardList( %score, %name, %mission)
{
   SortScoreBoardList();
   $ScoreBoard::Scores[4] = %score;
   $ScoreBoard::Names[4] = %name;
   $ScoreBoard::Mission[4] = %mission;
   
   echo(" New score added " @ %score SPC %name SPC %mission); 
   
   // save it to file, so its there later // 
   SaveScores(); 
}

//This function updates the StatsListView
function UpdateScoreBoardListView()
{
   if ( $ScoreBoard::isLoaded != true)
      LoadScores();    
...

It loads the scores from file, into memory when the screen is updated ... but only once. Then it saves the list each time a new score is added.

#2 maybe this will save some code space:

function SaveScores()
{

%dataFile = expandFilename("scripts/gui/scoreboard.txt");

export( "$save::*", %dataFile );
}


function LoadScores()
{

%dataFile = expandFilename("scripts/gui/scoreboard.txt");
exec(%dataFile);


// $ScoreBoard::isLoaded = true;
}

#3 Additionally, if you make all of your score information fields on a ScriptObject you can call ScriptObject.save(%filename) and then call ScriptObject.load(%filename) to load them.

More than one way to skin a cat....