Detecting *valid* resolutions?

$wideScreenIsOn = false;	// Default value

function toggleWidescreen()
{
	$wideScreenIsOn = !$wideScreenIsOn;
	handleWidescreenChange();
}

function setWidescreen(%isOn)
{
	$wideScreenIsOn = %isOn;
	handleWidescreenChange();
}

	// Call this when returning to original window size.
function resetWidescreen()
{
	%info = getRes();
	%width = getWord(%info, 0);
	%height = getWord(%info, 1);
	
		// Set everything to be that same resolution
	mainScreenGui.setExtent( %width, %height );
	sceneWindow2D.setExtent( %width, %height );
	sceneWindow2D.setPosition( 0, 0 );
}


	// NOTE: See "MainScreen.gui" in the "game/gui" folder for names of GUI elements
	// that we access directly here. ("sceneWindow2D" and "mainScreenGui")
	// I can add more GUI elements or rename them in that file.
function handleWidescreenChange()
{
	// Get the current resolution of our game *window* (not of the desktop)
		// NOTE: it's possible to be full-screen, and still a much lower resolution that the desktop res
	%info = getRes();
	%width = getWord(%info, 0);	// 1680
	%height = getWord(%info, 1);	// 1050
	
		// setExtent = set the size of the control
	mainScreenGui.setExtent( %width, %height );
	
	%info = sceneWindow2D.getExtent();
	%windowWidth = getWord(%info, 0);
	%windowHeight = getWord(%info, 1); 
	
	%ratio = 800 / 600;		// This is 1.333333333. Note that some displays may be LESS than OR MORE than this! (1.25, 1.6, etc.)
	%newWidth = mCeil( %height * %ratio );  // Determine what the "correct" width would be if aspect ratio > 1.33
	%newHeight = mFloor( %width / %ratio ); // Determine what the correct height would be if aspect ratio < 1.33
	
		// Is the window the correct size for the game anyway? Then don't allow any widescreen changes.
	%canHaveBlackBorders = (%newWidth != %windowWidth);
	
		// Also don't allow widescreen changes if the  aspect ratio of the display is already perfect (1.333333)
	if (%newWidth == %width)
		%canHaveBlackBorders = false;
	
		// Were we already widescreen? Then switch to black borders on the sides.
	if ($wideScreenIsOn == false && %canHaveBlackBorders)
	{
//		echo("Doing change.");
		
		// Put a black border on the sides? (Screen ratio is GREATER than 1.3333, such as 1.6 on my iMac)
		if (%newWidth < %windowWidth)
		{
			%borderSize = (%width - %newWidth) / 2; // i.e. (1680 - 1400) / 2 = 140  (size of black borders)
			
				// sceneWindow2D is a GUI control that is put INSIDE of the mainScreenGui control
			sceneWindow2D.setExtent( %newWidth, %height );
			sceneWindow2D.setPosition( %borderSize, 0 );
		}
		else	// Put a black border on the top and bottom (screen ratio is LESS than 1.3333!)
		{
			%borderSize = (%height - %newHeight) / 2;	// The black space goes at the *top* and *bottom* of the screen
			
			sceneWindow2D.setExtent( %width, %newHeight );
			sceneWindow2D.setPosition( 0, %borderSize );
		}
	}
	else
	{
			// Switch to fullscreen/widescreen (stretch or shrink to fit)
		sceneWindow2D.setExtent( %width, %height );
		sceneWindow2D.setPosition( 0, 0 );
	}
}

%guiContent = new GuiControl(mainScreenGui) {
   canSaveDynamicFields = "0";
   Profile = "GuiBlackContentProfile";
   HorizSizing = "width";
   VertSizing = "height";
   Position = "0 0";
   Extent = "1024 768";
   MinExtent = "8 8";
   canSave = "1";
   Visible = "1";
   useVariable = "0";
   
   new t2dSceneWindow(sceneWindow2D) {
      canSaveDynamicFields = "0";
      Profile = "GuiContentProfile";
      HorizSizing = "width";
      VertSizing = "height";
      Position = "0 0";
	  Extent = "1024 768";
      MinExtent = "8 8";
      canSave = "1";
      Visible = "1";
      lockMouse = "0";
      useWindowMouseEvents = "1";
      useObjectMouseEvents = "1";
   };
};