TGB NEWB QUESTION

by Trenton Moore · in Torque Game Builder · 11/04/2009 (6:46 am) · 1 replies · 11/06/2009 (5:44 am)

if(!isObject(platformerControlsBehavior))
{
   %template = new BehaviorTemplate(platformerControlsBehavior);
   
   %template.friendlyName = "Platformer Tutorial Controls";
   %template.behaviorType = "Input";
   %template.description  = "Movement control for a Platformer";
   
   %template.addBehaviorField(jumpKey, "Key to bind to jump movement", keybind, "Space");
   %template.addBehaviorField(leftKey, "Key to bind to left movement", keybind, "Left");
   %template.addBehaviorField(rightKey, "Key to bind to right movement", keybind, "Right");
   
   %template.addBehaviorField(runSpeed, "Speed when running", float, 60.0);
   %template.addBehaviorField(jumpSpeed, "Speed when jumping", float, 150.0);
}

function platformerControlsBehavior::onBehaviorAdd(%this)
{
   if (!isObject(moveMap))
      return;
   
   // bind our keys on the keyboard
   moveMap.bindObj(getWord(%this.jumpKey, 0), getWord(%this.jumpKey, 1), "jump", %this);
   moveMap.bindObj(getWord(%this.leftKey, 0), getWord(%this.leftKey, 1), "moveLeft", %this);
   moveMap.bindObj(getWord(%this.rightKey, 0), getWord(%this.rightKey, 1), "moveRight", %this);

   %this.left = 0;
   %this.right = 0;
	
	// Enable the update callback.
	%this.owner.enableUpdateCallback();
	
	// Set some collision stuffs.
	%this.owner.setCollisionMaxIterations(2);
}

// It appears that these are called once every tick...?
function platformerControlsBehavior::jump(%this, %val)
{
	if(!%this.owner.airborne)
		%this.launch(-%this.jumpSpeed);
}

function platformerControlsBehavior::moveLeft(%this, %val)
{
   %this.left = %val;
}

function platformerControlsBehavior::moveRight(%this, %val)
{
   %this.right = %val;
}

function platformerControlsBehavior::OnUpdate(%this)
{
	%this.updateHorizontal();
	%this.updateVertical();
	%this.setCurrentAnimation();
}

function platformerControlsBehavior::launch(%this, %speed)
{
	%this.owner.setLinearVelocityY(%speed);
	%this.owner.airborne = true;
}

// Called by onUpdate().
function platformerControlsBehavior::updateHorizontal(%this)
{
   // figure out what speed in what direction we are moving based on key input
	%newSpeed = (%this.right - %this.left) * %this.runSpeed;
   %this.owner.setLinearVelocityX(%newSpeed);
	
	// Clamp Vertical velocity on stop movement for up-ramps
	if(!%this.owner.airborne)
		%this.owner.setLinearVelocityY(0);
}

// Called by onUpdate().
function platformerControlsBehavior::updateVertical(%this)
{
	%yVelocity = %this.owner.getLinearVelocityY();
	
	if(%this.owner.airborne)
	{
		%this.owner.setLinearVelocityY(0);
		%collision = %this.owner.castCollision(0.005);
		
		if(%collision !$= "")
			%this.owner.setLinearVelocityX(0);
	}
	
	%this.owner.setLinearVelocityY(100);
	%collision = %this.owner.castCollision(0.005);
	
	if(%collision $= "")
	{
		%this.owner.airborne = true;
		%this.owner.setConstantForceY(100);
	}
	else if(%yVelocity < 0 && %this.owner.airborne)
	{
		%this.owner.setConstantForceY(100);
	}
	else
	{
		%this.owner.airborne = false;
		%this.owner.setConstantForceY(0);
	}
	
	%this.owner.setLinearVelocityY(%yVelocity);
}

// Called by onUpdate().
function platformerControlsBehavior::setCurrentAnimation(%this)
{
	%xVelocity = %this.owner.getLinearVelocityX();
	%yVelocity = %this.owner.getLinearVelocityY();
	
	// Set the flip of the avatar.
	if(%xVelocity > 0)
	{
		%this.owner.setFlip(false, false);
	}
	else if(%xVelocity < 0)
	{
		%this.owner.setFlip(true, false);
	}
	
	// Animations.
	if(%this.owner.airborne)
	{
		if(%yVelocity < 0)
			%this.owner.playAnimation(playerJumpUp);
		else
			%this.owner.playAnimation(playerJumpDown);
	}
	else
	{
		if(%xVelocity == 0)
		{
				%this.owner.playAnimation(playerStand);
		}
		else
		{
			if(%this.owner.getAnimationName() $= "playerRun")
			{
				if(%this.owner.getIsAnimationFinished())
					%this.owner.playAnimation(playerRun);
			}
			else
				%this.owner.playAnimation(playerRun);
		}
	}
}

Game Development Community

TGB NEWB QUESTION

About the author

Recent Threads