CoD Style MineField Triggers

Creating a "Ball of Fruity" style minefield.

This is a great way of creating an obstacle that the player cannot pass instead of using another wall or cliff as an element to contain the arena of gameplay.


FIRST UP, CREATE A NEW CS FILE IN SCRIPTS/SERVER FOLDER AND CALL IT

minefield.cs

We are going to use the stock explosion for the rocketlauncher as our minefield blast that can be found in "game/art/datablocks/weapons/rocketLauncher.cs"

datablock ExplosionData(RocketLauncherExplosion)
{
   soundProfile = RocketLauncherExplosionSound;
   lifeTimeMS = 200; // I want a quick bang and dissipation, not a slow burn-out

   // Volume particles
   particleEmitter = RocketExpSmokeEmitter;
   particleDensity = 10;//20;
   particleRadius = 1;//2;

   // Point emission
   emitter[0] = RocketExpFireEmitter;
   emitter[1] = RocketExpSparksEmitter;
   emitter[2] = RocketExpSparksEmitter;
   emitter[3] = RocketExpFireballEmitter;

   // Sub explosion objects
   subExplosion[0] = RocketSubExplosion;

   // Camera Shaking
   shakeCamera = true;
   camShakeFreq = "10.0 11.0 9.0";
   camShakeAmp = "15.0 15.0 15.0";
   camShakeDuration = 1.5;
   camShakeRadius = 20;

   // Exploding debris
   debris = RocketDebris;
   debrisThetaMin = 0;//10;
   debrisThetaMax = 90;//80;
   debrisNum = 5;
   debrisNumVariance = 2;
   debrisVelocity = 1;//2;
   debrisVelocityVariance = 0.2;//0.5;

   lightStartRadius = 6.0;
   lightEndRadius = 0.0;
   lightStartColor = "1.0 0.7 0.2";
   lightEndColor = "0.9 0.7 0.0";
   lightStartBrightness = 2.5;
   lightEndBrightness = 0.0;
   lightNormalOffset = 3.0;
};

We're going to make a trigger, and when a player runs into it, it's going to "spoil his day". For this, we need a dedicated trigger type. (Technically you could just make the trigger call a function but then you'd have to type that into every minefield trigger and that would be boring and time consuming)

Rather than have the player fatally stopped on touching the trigger, we can "randomize" it by using onTick. The player can enter teh trigger at any part of the trigger's tick, making the final explosion any time between 0 and 1000m/s, this can let them run a little way inside before having the explosion go off.

For this to happen, we'll use the onTick function rather than the onEnter function and set it to 1000m/s = 1 second. If you have a very deep minefield trigger you could set it to longer - just don't set it to a length that the player can run all the way through it and escape.

datablock TriggerData(MineFieldTrigger)
{
   // The period is value is used to control how often the console
   // onTriggerTick callback is called while there are any objects
   // in the trigger.  The default value is 100 MS.
   tickPeriodMS = 1000;
};

function MineFieldTrigger::onTickTrigger(%this,%trigger)
{
   // This method is called every tickPerioMS, as long as any
   // objects intersect the trigger.

   // You can iterate through the objects in the list by using these
   // methods:
   //    %trigger.getNumObjects();
   //    %trigger.getObject(n);
   
    %poor_fools = %trigger.getNumObjects();
	for(%x=0; %x < %poor_fools; %x++)
	{
		%mr_unlucky = %trigger.getObject(%x);
		
		//check it's a player! Also check it's not already dead - shouldn't be re-exploding on corpses
		//No point trying to blow up something we can't blow up
		//there are other things with trigger callbacks which may not be damageable
		//eg: items 
		//player classname is good for Ai too
		if(%mr_unlucky.getClassName() $="Player" && %mr_unlucky.getState() !$="Dead")
		{
		    //and spawn the stock grenadelauncher explosion
			%blast = new explosion()
			{
				dataBlock = "RocketLauncherExplosion";
				position = %mr_unlucky.getPosition();
			};
			MissionCleanup.add(%blast);
			
			//and kill the player outright
			%mr_unlucky.kill();
		}
	}
}

And lastly - for the scripting at least - we need to exec our new file
Open up scripts/server/scriptExec.cs
And right at the bottom add:

//...
	// Load our gametypes
	exec("./gameCore.cs"); // This is the 'core' of the gametype functionality.
	exec("./gameDM.cs"); // Overrides GameCore with DeathMatch functionality.

	exec("./minefield.cs"); // yorks new, right at the end

Boot up Torque3D and open the editor. Go into camera mode to make things easier.
Place a trigger via "Scene Tree -> Library -> Level -> Level -> Trigger", and for datablock choose our new "minefieldTrigger". Hit "create new" and then scale it in the inspector any way you like, it's best not to make it too high as you don't want explosions in midair.

As a final addition you'll need to make some models for signposts, informing the player that there is a minefield there ... or else they're going to get a great big WTF of a surprise and wonder why they died. Liberally place these warning signs outside your minefield trigger so that they can always be clearly seen. If a player runs into a minefield it should be because of their personal negligence and not because it was impossible for them to tell that there was a minefield there.



Maybe it should say "Don't Step Off The Road" instead of "slow" ...


Back when I was modding my own single player levels and campaigns for "Ball of Fruity 1 and 2" I'd often have a friendly Ai run into the minefield as an extra method of warning the player not to go into it.

Anyhow, here is what it'll look like without any signs, but with the trigger visible for debug.