Path Following AI Vehicles Through TorqueScript

NOTE: If you are using Torque 3D Pro or TGEA, please go to my other resource here in order to get the AIWheeledVehicle class into the engine! Without it, this resource won't work. Once that is done, you can implement this resource.

In Torque, the AIWheeledVehicle class is a very useful class to get you started with AI vehicles driving around. The only problem is that they can't follow paths like AI players can out of the box. There is an excellent resource by Mr. Brian McGavin (www.torquepowered.com/community/resources/view/8836) that adds this path-following functionality by modifying the Torque source code.

In this resource though, we are going to implement the same kind of functionality to allow stock AIWheeledVehicles to follow a path without any engine modification at all; just utilizing the object functions exposed to TorqueScript out of the box.

Here is the TorqueScript script file you need to use:

//The AICarManager object is a script object used
//for updating AIWheeledVehicles. It allows them to
//follow in game paths without modification to the
//source code of the engine.

//By Quentin Headen

new ScriptObject(AICarManager)
{
   botGroup = 0; //A SimGroup object containing all of the ai cars (bots)
   arrivedDistance = 8; //The distance from the destination that the bot can say it arrived
   updateSpeed = 100; //The speed at which the manager rechecks the bots
   botMoveSpeed = 0.5; //The movement speed of the bots. Start at half.
   thinkSchedule = 0; //The schedule to update the thinking
};

function AICarManager::think(%this)
{   
   //If the bot group isn't set
   if(!isObject(%this.botGroup))
   {
      //Show an error and return
      error("You must set the botGroup SimGroup using setBotGroup before thinking can occur!");
      return;
   }
   
   //For each vehicle bot in the bot group
   for(%i = 0; %i < %this.botGroup.getCount(); %i++)
   {
      //Get the bot object
      %bot = %this.botGroup.getObject(%i);
      
      //If the path for this vehicle bot
      //is set
      if(isObject(%bot.path))
      {
         //Check the distance from the bot to its current path node
         %distance = VectorDist(%bot.getPosition(), %bot.path.getObject(%bot.pathNode).getPosition());
         
         //If the distance is less than the arrived distance
         if(%distance < %this.arrivedDistance)
         {
            //Move to the next node
            %bot.pathNode++;
            
            //If that node dosen't exist
            if(%bot.pathNode > %bot.path.getCount() - 1)
            {
               //Move back to the beginning node
               %bot.pathNode = 0;
            }
            
            //Set the updated move destination
            %bot.setMoveDestination(%bot.path.getObject(%bot.pathNode).getPosition());
         }
      }
   }
   
   //Continue to think
   %this.thinkSchedule = %this.schedule(%this.updateSpeed, think);
}

function AICarManager::startBot(%this, %bot, %path)
{
   //If the bot group doesn't exist
   if(!isObject(%this.botGroup))
   {
      //Create it
      %this.botGroup = new SimGroup();
   }
   
   //If this bot isn't a member of the bot group
   if(!%this.botGroup.isMember(%bot))
   {
      //Add it
      %this.botGroup.add(%bot);
   }
   
   //Set the starting path and path node for the bot
   %bot.path = %path;
   %bot.pathNode = 0;
   
   //Start the car to moving
   %bot.setMoveSpeed(%this.botMoveSpeed);
   %bot.setMoveDestination(%path.getObject(0).getPosition());
}

function AICarManager::stopBot(%this, %bot)
{
   //If the bot is in the bot group
   if(%this.botGroup.isMember(%bot))
   {
      //Stop it
      %bot.stop();
      
      //Remove it from the manager
      %this.botGroup.remove(%bot);
   }
}

function AiCarManager::stopThinking(%this)
{
   //Cancel the updating of the think() function
   cancel(%this.thinkSchedule);
   
   //For each car in the bot group
   for(%i = 0; %i < %this.botGroup.getCount(); %i++)
   {
      //Stop it
      %this.botGroup.getObject(%i).stop();
   }
}

I know you probably don't believe that this is the only script you have to add. Don't feel bad, I almost didn't believe it myself. :P

To see this script in action, open up a mission, create a path, create an AIWheeledVehicle and then call AICarManager.startBot(BotNameOrID, PathNameOrID); Remember that "BotNameOrID" is equal to the name or ID of the AIWheeledVehicle you want to follow a path and "PathNameOrID" is equal to the name or ID of the path your desired bot should follow. After that, the car will begin to move. MAKE SURE that you call AICarManager.think() right after this or the car won't follow the path, but will be stuck at the first node of the path. If you ever need to stop all of your bots from following the path, just call AICarManager.stopThinking(). This will kill the think loop and stop all of the bots added to this manager. To stop a single bot, just call AICarManager.stopBot(BotNameOrID), with once again BotNameOrID meaning the name or ID of the bot you want to stop.

Please note that this script isn't completely done. I have some extra things I want to add such as slowing down the car when it approches a node.

Hmm... What else is there to tell you? I know it was something extra I had to tell you about this script... Oh yeah, I remember! I wanted to tell you to HAVE FUN! :)

Please make comments on the script to let me know how you like it and what improvements can be made.


Edit: Changed the way the script determines if there is a next node. The old method littered the console with getObject() out of range errors.